import org.apache.tools.ant.filters.ReplaceTokens
import org.gradle.internal.os.OperatingSystem
import org.gradle.plugins.ide.eclipse.model.Output
import org.gradle.plugins.ide.eclipse.model.Library
import java.security.MessageDigest

import groovy.transform.ExternalizeMethods

buildscript {
  dependencies {
    classpath 'org.openclover:clover:4.3.1'
  }
}

plugins {
  id 'java'
  id 'application'
  id 'eclipse'
  id 'com.github.johnrengelman.shadow' version '4.0.3'
  id 'com.install4j.gradle' version '7.0.9'
  id 'com.dorongold.task-tree' version '1.4' // only needed to display task dependency tree with  gradle task1 [task2 ...] taskTree
}

repositories {
  jcenter()
  mavenCentral()
  mavenLocal()
  flatDir {
    dirs gradlePluginsDir
  }
}

dependencies {
  compile 'org.apache.commons:commons-compress:1.18'
}


// in ext the values are cast to Object. Ensure string values are cast as String (and not GStringImpl) for later use
def string(Object o) {
  return o.toString()
}


ext {
  jalviewDirAbsolutePath = file(jalviewDir).getAbsolutePath()
  jalviewDirRelativePath = jalviewDir

  // local build environment properties
  def localProps = "${jalviewDirAbsolutePath}/local.properties"
  if (file(localProps).exists()) {
    try {
      def p = new Properties()
      def localPropsFIS = new FileInputStream(localProps)
      p.load(localPropsFIS)
      localPropsFIS.close()
      p.each {
        key, val -> 
          def over = getProperty(key) != null
          setProperty(key, val)
          if (over) {
            println("Overriding property '${key}' with local.properties value '${val}'")
          }
      }
    } catch (Exception e) {
      System.out.println("Exception reading local.properties")
    }
  }

  // this property set when running Eclipse headlessly
  j2sHeadlessBuildProperty = string("net.sf.j2s.core.headlessbuild")
  // this property set by Eclipse
  eclipseApplicationProperty = string("eclipse.application")
  // CHECK IF RUNNING FROM WITHIN ECLIPSE
  def eclipseApplicationPropertyVal = System.properties[eclipseApplicationProperty]
  IN_ECLIPSE = eclipseApplicationPropertyVal != null && eclipseApplicationPropertyVal.startsWith("org.eclipse.ui.")
  // BUT WITHOUT THE HEADLESS BUILD PROPERTY SET
  if (System.properties[j2sHeadlessBuildProperty].equals("true")) {
    println("Setting IN_ECLIPSE to ${IN_ECLIPSE} as System.properties['${j2sHeadlessBuildProperty}'] == '${System.properties[j2sHeadlessBuildProperty]}'")
    IN_ECLIPSE = false
  }
  if (IN_ECLIPSE) {
    println("WITHIN ECLIPSE IDE")
  } else {
    println("HEADLESS BUILD")
  }
  
  J2S_ENABLED = (project.hasProperty('j2s.compiler.status') && project['j2s.compiler.status'] != null && project['j2s.compiler.status'] == "enable")
  if (J2S_ENABLED) {
    println("J2S ENABLED")
  }
  
  /* *-/
  System.properties.sort { it.key }.each {
    key, val -> println("SYSTEM PROPERTY ${key}='${val}'")
  }
  /-* *-/
  if (false && IN_ECLIPSE) {
    jalviewDir = jalviewDirAbsolutePath
  }
  */

  // essentials
  bareSourceDir = string(source_dir)
  sourceDir = string("${jalviewDir}/${bareSourceDir}")
  resourceDir = string("${jalviewDir}/${resource_dir}")
  bareTestSourceDir = string(test_source_dir)
  testSourceDir = string("${jalviewDir}/${bareTestSourceDir}")

  // clover
  cloverInstrDir = file("${buildDir}/${cloverSourcesInstrDir}")
  classesDir = string("${jalviewDir}/${classes_dir}")
  if (clover.equals("true")) {
    use_clover = true
    classesDir = string("${buildDir}/${cloverClassesDir}")
  } else {
    use_clover = false
    classesDir = string("${jalviewDir}/${classes_dir}")
  }

  classes = classesDir

  getdownWebsiteDir = string("${jalviewDir}/${getdown_website_dir}/${JAVA_VERSION}")
  getdownDir = string("")
  reportRsyncCmd = false
  buildDist = true
  buildProperties = string("${resourceDir}/${build_properties_file}")
  getdownLauncher = string("${jalviewDir}/${getdown_lib_dir}/${getdown_launcher}")
  switch (CHANNEL) {

    case "BUILD":
    // TODO: get bamboo build artifact URL for getdown artifacts
    getdown_channel_base = bamboo_channelbase
    getdown_channel_name = string("${bamboo_planKey}/${JAVA_VERSION}")
    getdown_app_base = string("${bamboo_channelbase}/${bamboo_planKey}${bamboo_getdown_channel_suffix}/${JAVA_VERSION}")
    getdown_app_dir = getdown_app_dir_alt
    buildProperties = string("${resourceDir}/${build_properties_file}")
    break

    case "RELEASE":
    getdown_channel_name = CHANNEL.toLowerCase()
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = string("${getdown_channel_base}/${getdownDir}")
    getdown_app_dir = getdown_app_dir_release
    buildProperties = string("${resourceDir}/${build_properties_file}")
    reportRsyncCommand = true
    break

    case "ARCHIVE":
    getdown_channel_name = CHANNEL.toLowerCase()+"/${JALVIEW_VERSION}"
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = string("${getdown_channel_base}/${getdownDir}")
    getdown_app_dir = getdown_app_dir_alt
    if (!file("${ARCHIVEDIR}/${packageDir}").exists()) {
      print "Must provide an ARCHIVEDIR value to produce an archive distribution"
      exit
    } else {
      packageDir = string("${ARCHIVEDIR}/${packageDir}")
      buildProperties = string("${ARCHIVEDIR}/${resource_dir}/${build_properties_file}")
      buildDist = false
    }
    reportRsyncCommand = true
    break

    case "ARCHIVELOCAL":
    getdown_channel_name = string("archive/${JALVIEW_VERSION}")
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = file(getdownWebsiteDir).toURI().toString()
    getdown_app_dir = getdown_app_dir_alt
    if (!file("${ARCHIVEDIR}/${packageDir}").exists()) {
      print "Must provide an ARCHIVEDIR value to produce an archive distribution"
      exit
    } else {
      packageDir = string("${ARCHIVEDIR}/${packageDir}")
      buildProperties = string("${ARCHIVEDIR}/${resource_dir}/${build_properties_file}")
      buildDist = false
    }
    reportRsyncCommand = true
    getdownLauncher = string("${jalviewDir}/${getdown_lib_dir}/${getdown_launcher_local}")
    break

    case "DEVELOP":
    getdown_channel_name = CHANNEL.toLowerCase()
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = string("${getdown_channel_base}/${getdownDir}")
    getdown_app_dir = getdown_app_dir_alt
    buildProperties = string("${resourceDir}/${build_properties_file}")
    reportRsyncCommand = true
    break

    case "TEST-RELEASE":
    getdown_channel_name = CHANNEL.toLowerCase()
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = string("${getdown_channel_base}/${getdownDir}")
    getdown_app_dir = getdown_app_dir_alt
    buildProperties = string("${resourceDir}/${build_properties_file}")
    reportRsyncCommand = true
    break

    case ~/^SCRATCH(|-[-\w]*)$/:
    getdown_channel_name = CHANNEL
    getdownDir = string("${getdown_channel_name}/${JAVA_VERSION}")
    getdown_app_base = string("${getdown_channel_base}/${getdownDir}")
    getdown_app_dir = getdown_app_dir_alt
    buildProperties = string("${resourceDir}/${build_properties_file}")
    reportRsyncCommand = true
    break

    case "LOCAL":
    getdown_app_base = file(getdownWebsiteDir).toURI().toString()
    getdown_app_dir = getdown_app_dir_alt
    buildProperties = string("${resourceDir}/${build_properties_file}")
    getdownLauncher = string("${jalviewDir}/${getdown_lib_dir}/${getdown_launcher_local}")
    break

    default: // something wrong specified
    print("CHANNEL must be one of BUILD, RELEASE, ARCHIVE, DEVELOP, TEST-RELEASE, SCRATCH-..., LOCAL [default]")
    exit
    break

  }

  getdownAppDir = string("${getdownWebsiteDir}/${getdown_app_dir}")
  //getdownJ11libDir = "${getdownWebsiteDir}/${getdown_j11lib_dir}"
  getdownResourceDir = string("${getdownWebsiteDir}/${getdown_resource_dir}")
  getdownInstallDir = string("${getdownWebsiteDir}/${getdown_install_dir}")
  getdownFilesDir = string("${jalviewDir}/${getdown_files_dir}/${JAVA_VERSION}/")
  getdownFilesInstallDir = string("${getdownFilesDir}/${getdown_install_dir}")
  /* compile without modules -- using classpath libraries
  modules_compileClasspath = fileTree(dir: "${jalviewDir}/${j11modDir}", include: ["*.jar"])
  modules_runtimeClasspath = modules_compileClasspath
  */
  gitHash = string("")
  gitBranch = string("")

  println("Using a ${CHANNEL} profile.")

  additional_compiler_args = []
  // configure classpath/args for j8/j11 compilation
  if (JAVA_VERSION.equals("1.8")) {
    JAVA_INTEGER_VERSION = string("8")
    //libDir = j8libDir
    libDir = j11libDir
    libDistDir = j8libDir
    compile_source_compatibility = 1.8
    compile_target_compatibility = 1.8
    // these are getdown.txt properties defined dependent on the JAVA_VERSION
    getdown_alt_java_min_version = getdown_alt_java8_min_version
    getdown_alt_java_max_version = getdown_alt_java8_max_version
    // this property is assigned below and expanded to multiple lines in the getdown task
    getdown_alt_multi_java_location = getdown_alt_java8_txt_multi_java_location
    // this property is for the Java library used in eclipse
    eclipse_java_runtime_name = string("JavaSE-1.8")
  } else if (JAVA_VERSION.equals("11")) {
    JAVA_INTEGER_VERSION = string("11")
    libDir = j11libDir
    libDistDir = j11libDir
    compile_source_compatibility = 11
    compile_target_compatibility = 11
    getdown_alt_java_min_version = getdown_alt_java11_min_version
    getdown_alt_java_max_version = getdown_alt_java11_max_version
    getdown_alt_multi_java_location = getdown_alt_java11_txt_multi_java_location
    eclipse_java_runtime_name = string("JavaSE-11")
    /* compile without modules -- using classpath libraries
    additional_compiler_args += [
    '--module-path', modules_compileClasspath.asPath,
    '--add-modules', j11modules
    ]
     */
  } else if (JAVA_VERSION.equals("12") || JAVA_VERSION.equals("13")) {
    JAVA_INTEGER_VERSION = JAVA_VERSION
    libDir = j11libDir
    libDistDir = j11libDir
    compile_source_compatibility = JAVA_VERSION
    compile_target_compatibility = JAVA_VERSION
    getdown_alt_java_min_version = getdown_alt_java11_min_version
    getdown_alt_java_max_version = getdown_alt_java11_max_version
    getdown_alt_multi_java_location = getdown_alt_java11_txt_multi_java_location
    eclipse_java_runtime_name = string("JavaSE-11")
    /* compile without modules -- using classpath libraries
    additional_compiler_args += [
    '--module-path', modules_compileClasspath.asPath,
    '--add-modules', j11modules
    ]
     */
  } else {
    throw new GradleException("JAVA_VERSION=${JAVA_VERSION} not currently supported by Jalview")
  }


  // for install4j
  macosJavaVMDir = string("${System.env.HOME}/buildtools/jre/openjdk-java_vm/getdown/macos-jre${JAVA_VERSION}/jre")
  macosJavaVMTgz = string("${System.env.HOME}/buildtools/jre/openjdk-java_vm/install4j/tgz/macos-jre${JAVA_VERSION}.tar.gz")
  windowsJavaVMDir = string("${System.env.HOME}/buildtools/jre/openjdk-java_vm/getdown/windows-jre${JAVA_VERSION}/jre")
  windowsJavaVMTgz = string("${System.env.HOME}/buildtools/jre/openjdk-java_vm/install4j/tgz/windows-jre${JAVA_VERSION}.tar.gz")
  install4jDir = string("${jalviewDir}/${install4jResourceDir}")
  install4jConfFileName = string("jalview-installers-java${JAVA_VERSION}.install4j")
  install4jConfFile = string("${install4jDir}/${install4jConfFileName}")


  buildingHTML = string("${jalviewDir}/${docDir}/building.html")
  helpFile = string("${classesDir}/${help_dir}/help.jhm")
  helpParentDir = string("${jalviewDir}/${help_parent_dir}")
  helpDir = string("${help_dir}")
  helpSourceDir = string("${helpParentDir}/${helpDir}")


  relativeBuildDir = file(jalviewDirAbsolutePath).toPath().relativize(buildDir.toPath())
  jalviewjsBuildDir = string("${relativeBuildDir}/jalviewjs")
  jalviewjsSiteDir = string("${jalviewjsBuildDir}/${jalviewjs_site_dir}")
  if (IN_ECLIPSE) {
    jalviewjsTransferSiteJsDir = string(jalviewjsSiteDir)
  } else {
    jalviewjsTransferSiteJsDir = string("${jalviewjsBuildDir}/tmp/${jalviewjs_site_dir}_js")
  }
  jalviewjsTransferSiteLibDir = string("${jalviewjsBuildDir}/tmp/${jalviewjs_site_dir}_lib")
  jalviewjsTransferSiteSwingJsDir = string("${jalviewjsBuildDir}/tmp/${jalviewjs_site_dir}_swingjs")
  jalviewjsTransferSiteCoreDir = string("${jalviewjsBuildDir}/tmp/${jalviewjs_site_dir}_core")
  jalviewjsJalviewCoreHtmlFile = string("")
  jalviewjsJalviewCoreName = string(jalviewjs_core_name)
  jalviewjsCoreClasslists = []
  jalviewjsJalviewTemplateName = string(jalviewjs_name)
  jalviewjsJ2sSettingsFileName = string("${jalviewDir}/${jalviewjs_j2s_settings}")
  jalviewjsJ2sProps = null

  eclipseWorkspace = null
  eclipseBinary = string("")
  eclipseVersion = string("")
  eclipseDebug = false
  // ENDEXT
}


sourceSets {
  main {
    java {
      srcDirs sourceDir
      outputDir = file(classesDir)
    }

    resources {
      srcDirs resourceDir
    }

    jar.destinationDir = file("${jalviewDir}/${packageDir}")

    compileClasspath = files(sourceSets.main.java.outputDir)
    compileClasspath += fileTree(dir: "${jalviewDir}/${libDir}", include: ["*.jar"])

    runtimeClasspath = compileClasspath
  }

  clover {
    java {
      srcDirs = [ cloverInstrDir ]
      outputDir = file("${buildDir}/${cloverClassesDir}")
    }

    resources {
      srcDirs = sourceSets.main.resources.srcDirs
    }
    compileClasspath = configurations.cloverRuntime + files( sourceSets.clover.java.outputDir )
    compileClasspath += files(sourceSets.main.java.outputDir)
    compileClasspath += sourceSets.main.compileClasspath
    compileClasspath += fileTree(dir: "${jalviewDir}/${utilsDir}", include: ["**/*.jar"])
    compileClasspath += fileTree(dir: "${jalviewDir}/${libDir}", include: ["*.jar"])

    runtimeClasspath = compileClasspath
  }

  test {
    java {
      srcDirs testSourceDir
      outputDir = file("${jalviewDir}/${testOutputDir}")
    }

    resources {
      srcDirs = sourceSets.main.resources.srcDirs
    }

    compileClasspath = files( sourceSets.test.java.outputDir )

    if (use_clover) {
      compileClasspath += sourceSets.clover.compileClasspath
    } else {
      compileClasspath += files(sourceSets.main.java.outputDir)
    }

    compileClasspath += fileTree(dir: "${jalviewDir}/${libDir}", include: ["*.jar"])
    compileClasspath += fileTree(dir: "${jalviewDir}/${utilsDir}/testnglibs", include: ["**/*.jar"])
    compileClasspath += fileTree(dir: "${jalviewDir}/${utilsDir}/testlibs", include: ["**/*.jar"])

    runtimeClasspath = compileClasspath
  }
}


// clover bits
dependencies {
  if (use_clover) {
    cloverCompile 'org.openclover:clover:4.3.1'
    testCompile 'org.openclover:clover:4.3.1'
  }
}


configurations {
  cloverRuntime
  cloverRuntime.extendsFrom cloverCompile
}

eclipse {
  project {
    name = eclipse_project_name

    natures 'org.eclipse.jdt.core.javanature',
    'org.eclipse.jdt.groovy.core.groovyNature',
    'org.eclipse.buildship.core.gradleprojectnature'

    buildCommand 'org.eclipse.jdt.core.javabuilder'
    buildCommand 'org.eclipse.buildship.core.gradleprojectbuilder'
  }

  classpath {
    //defaultOutputDir = sourceSets.main.java.outputDir
    def removeThese = []
    configurations.each{
      if (it.isCanBeResolved()) {
        removeThese += it
      }
    }

    minusConfigurations += removeThese
    plusConfigurations = [ ]
    file {

      whenMerged { cp ->
        def removeTheseToo = []
        HashMap<String, Boolean> alreadyAddedSrcPath = new HashMap<>();
        cp.entries.each { entry ->
          // This conditional removes all src classpathentries that a) have already been added or b) aren't "src" or "test".
          // e.g. this removes the resources dir being copied into bin/main, bin/test AND bin/clover
          // we add the resources and help/help dirs in as libs afterwards (see below)
          if (entry.kind == 'src') {
            if (alreadyAddedSrcPath.getAt(entry.path) || !(entry.path == bareSourceDir || entry.path == bareTestSourceDir)) {
              removeTheseToo += entry
            } else {
              alreadyAddedSrcPath.putAt(entry.path, true)
            }
          }

        }
        cp.entries.removeAll(removeTheseToo)

        cp.entries += new Output("${eclipse_bin_dir}/main")
        if (file(helpSourceDir).isDirectory()) {
          cp.entries += new Library(fileReference(helpSourceDir))
        }
        if (file(resourceDir).isDirectory()) {
          cp.entries += new Library(fileReference(resourceDir))
        }

        HashMap<String, Boolean> alreadyAddedLibPath = new HashMap<>();

        sourceSets.main.compileClasspath.findAll { it.name.endsWith(".jar") }.each {
          //don't want to add outputDir as eclipse is using its own output dir in bin/main
          if (it.isDirectory() || ! it.exists()) {
            // don't add dirs to classpath, especially if they don't exist
            return false // groovy "continue" in .any closure
          }
          def itPath = it.toString()
          if (itPath.startsWith("${jalviewDirAbsolutePath}/")) {
            // make relative path
            itPath = itPath.substring(jalviewDirAbsolutePath.length()+1)
          }
          if (alreadyAddedLibPath.get(itPath)) {
            //println("Not adding duplicate entry "+itPath)
          } else {
            //println("Adding entry "+itPath)
            cp.entries += new Library(fileReference(itPath))
            alreadyAddedLibPath.put(itPath, true)
          }
        }

        //fileTree(dir: "$jalviewDir/$utilsDir", include: ["test*/*.jar"]).each {
        sourceSets.test.compileClasspath.findAll { it.name.endsWith(".jar") }.any {
          //no longer want to add outputDir as eclipse is using its own output dir in bin/main
          if (it.isDirectory() || ! it.exists()) {
            // don't add dirs to classpath
            return false // groovy "continue" in .any closure
          }

          def itPath = it.toString()
          if (itPath.startsWith("${jalviewDirAbsolutePath}/")) {
            itPath = itPath.substring(jalviewDirAbsolutePath.length()+1)
          }
          if (alreadyAddedLibPath.get(itPath)) {
            // don't duplicate
          } else {
            def lib = new Library(fileReference(itPath))
            lib.entryAttributes["test"] = "true"
            cp.entries += lib
            alreadyAddedLibPath.put(itPath, true)
          }
        }

      } // whenMerged

    } // file

    containers 'org.eclipse.buildship.core.gradleclasspathcontainer'

  } // classpath

  jdt {
    // for the IDE, use java 11 compatibility
    sourceCompatibility = compile_source_compatibility
    targetCompatibility = compile_target_compatibility
    javaRuntimeName = eclipse_java_runtime_name

    // add in jalview project specific properties/preferences into eclipse core preferences
    file {
      withProperties { props ->
        def jalview_prefs = new Properties()
        def ins = new FileInputStream("${jalviewDirAbsolutePath}/${eclipse_extra_jdt_prefs_file}")
        jalview_prefs.load(ins)
        ins.close()
        jalview_prefs.forEach { t, v ->
          if (props.getAt(t) == null) {
            props.putAt(t, v)
          }
        }
      }
    }

  } // jdt

  if (IN_ECLIPSE) {
    // Don't want these to be activated if in headless build
    synchronizationTasks "eclipseSynchronizationTask"
    //autoBuildTasks "eclipseAutoBuildTask"

  }
}


task cloverInstr() {
  // only instrument source, we build test classes as normal
  inputs.files files (sourceSets.main.allJava) // , fileTree(dir: testSourceDir, include: ["**/*.java"]))
  outputs.dir cloverInstrDir

  doFirst {
    delete cloverInstrDir
    def argsList = ["--initstring", "${buildDir}/clover/clover.db",
    "-d", "${buildDir}/${cloverSourcesInstrDir}"]
    argsList.addAll(inputs.files.files.collect({ file ->
      file.absolutePath
    }))
    String[] args = argsList.toArray()
    println("About to instrument "+args.length +" files")
    com.atlassian.clover.CloverInstr.mainImpl(args)
  }
}


task cloverReport {
  group = "Verification"
    description = "Createst the Clover report"
    inputs.dir "${buildDir}/clover"
    outputs.dir "${reportsDir}/clover"
    onlyIf {
      file("${buildDir}/clover/clover.db").exists()
    }
  doFirst {
    def argsList = ["--initstring", "${buildDir}/clover/clover.db",
    "-o", "${reportsDir}/clover"]
    String[] args = argsList.toArray()
    com.atlassian.clover.reporters.html.HtmlReporter.runReport(args)

    // and generate ${reportsDir}/clover/clover.xml
    args = ["--initstring", "${buildDir}/clover/clover.db",
    "-o", "${reportsDir}/clover/clover.xml"].toArray()
    com.atlassian.clover.reporters.xml.XMLReporter.runReport(args)
  }
}
// end clover bits


compileJava {

  doFirst {
    sourceCompatibility = compile_source_compatibility
    targetCompatibility = compile_target_compatibility
    options.compilerArgs = additional_compiler_args
    print ("Setting target compatibility to "+targetCompatibility+"\n")
  }

}


compileTestJava {
  if (use_clover) {
    dependsOn compileCloverJava
    classpath += configurations.cloverRuntime
  } else {
    classpath += sourceSets.main.runtimeClasspath
  }
  doFirst {
    sourceCompatibility = compile_source_compatibility
    targetCompatibility = compile_target_compatibility
    options.compilerArgs = additional_compiler_args
    print ("Setting target compatibility to "+targetCompatibility+"\n")
  }
}


compileCloverJava {

  doFirst {
    sourceCompatibility = compile_source_compatibility
    targetCompatibility = compile_target_compatibility
    options.compilerArgs += additional_compiler_args
    print ("Setting target compatibility to "+targetCompatibility+"\n")
  }
  classpath += configurations.cloverRuntime
}


clean {
  doFirst {
    delete sourceSets.main.java.outputDir
  }
}


cleanTest {
  doFirst {
    delete sourceSets.test.java.outputDir
    delete cloverInstrDir
  }
}


// format is a string like date.format("dd MMMM yyyy")
def getDate(format) {
  def date = new Date()
  return date.format(format)
}


task setGitVals {
  def hashStdOut = new ByteArrayOutputStream()
  exec {
    commandLine "git", "rev-parse", "--short", "HEAD"
    standardOutput = hashStdOut
    ignoreExitValue true
  }

  def branchStdOut = new ByteArrayOutputStream()
  exec {
    commandLine "git", "rev-parse", "--abbrev-ref", "HEAD"
    standardOutput = branchStdOut
    ignoreExitValue true
  }

  gitHash = hashStdOut.toString().trim()
  gitBranch = branchStdOut.toString().trim()

  outputs.upToDateWhen { false }
}


task createBuildProperties(type: WriteProperties) {
  group = "build"
  description = "Create the ${buildProperties} file"
  dependsOn setGitVals
  inputs.dir(sourceDir)
  inputs.dir(resourceDir)
  file(buildProperties).getParentFile().mkdirs()
  outputFile (buildProperties)
  // taking time specific comment out to allow better incremental builds
  comment "--Jalview Build Details--\n"+getDate("yyyy-MM-dd HH:mm:ss")
  //comment "--Jalview Build Details--\n"+getDate("yyyy-MM-dd")
  property "BUILD_DATE", getDate("HH:mm:ss dd MMMM yyyy")
  property "VERSION", JALVIEW_VERSION
  property "INSTALLATION", INSTALLATION+" git-commit:"+gitHash+" ["+gitBranch+"]"
  outputs.file(outputFile)
}


clean {
  doFirst {
    delete buildProperties
  }
}


task cleanBuildingHTML(type: Delete) {
  doFirst {
    delete buildingHTML
  }
}


task convertBuildingMD(type: Exec) {
  dependsOn cleanBuildingHTML
  def buildingMD = "${jalviewDir}/${docDir}/building.md"
  def css = "${jalviewDir}/${docDir}/github.css"

  def pandoc = null
  pandoc_exec.split(",").each {
    if (file(it.trim()).exists()) {
      pandoc = it.trim()
      return true
    }
  }

  def hostname = "hostname".execute().text.trim()
  if ((pandoc == null || ! file(pandoc).exists()) && hostname.equals("jv-bamboo")) {
    pandoc = System.getProperty("user.home")+"/buildtools/pandoc/bin/pandoc"
  }

  doFirst {
    if (pandoc != null && file(pandoc).exists()) {
        commandLine pandoc, '-s', '-o', buildingHTML, '--metadata', 'pagetitle="Building Jalview from Source"', '--toc', '-H', css, buildingMD
    } else {
        println("Cannot find pandoc. Skipping convert building.md to HTML")
        throw new StopExecutionException("Cannot find pandoc. Skipping convert building.md to HTML")
    }
  }

  ignoreExitValue true

  inputs.file(buildingMD)
  inputs.file(css)
  outputs.file(buildingHTML)
}


clean {
  doFirst {
    delete buildingHTML
  }
}


task syncDocs(type: Sync) {
  dependsOn convertBuildingMD
  def syncDir = "${classesDir}/${docDir}"
  from fileTree("${jalviewDir}/${docDir}")
  into syncDir

}


task copyHelp(type: Copy) {
  def inputDir = helpSourceDir
  def outputDir = "${classesDir}/${helpDir}"
  from(inputDir) {
    exclude '**/*.gif'
    exclude '**/*.jpg'
    exclude '**/*.png'
    filter(ReplaceTokens,
      beginToken: '$$',
      endToken: '$$',
      tokens: [
        'Version-Rel': JALVIEW_VERSION,
        'Year-Rel': getDate("yyyy")
      ]
    )
  }
  from(inputDir) {
    include '**/*.gif'
    include '**/*.jpg'
    include '**/*.png'
  }
  into outputDir

  inputs.dir(inputDir)
  outputs.files(helpFile)
  outputs.dir(outputDir)
}


task syncLib(type: Sync) {
  def syncDir = "${classesDir}/${libDistDir}"
  from fileTree("${jalviewDir}/${libDistDir}")
  into syncDir
}


task syncResources(type: Sync) {
  dependsOn createBuildProperties
  from resourceDir
  include "**/*.*"
  into "${classesDir}"
  preserve {
    include "**"
  }
}


task prepare {
  dependsOn syncResources
  dependsOn syncDocs
  dependsOn copyHelp
}


//testReportDirName = "test-reports" // note that test workingDir will be $jalviewDir
test {
  dependsOn prepare
  dependsOn compileJava
  if (use_clover) {
    dependsOn cloverInstr
  }

  if (use_clover) {
    print("Running tests " + (use_clover?"WITH":"WITHOUT") + " clover [clover="+use_clover+"]\n")
  }

  useTestNG() {
    includeGroups testngGroups
    preserveOrder true
    useDefaultListeners=true
  }

  workingDir = jalviewDir
  //systemProperties 'clover.jar' System.properties.clover.jar
  sourceCompatibility = compile_source_compatibility
  targetCompatibility = compile_target_compatibility
  jvmArgs += additional_compiler_args

}


task buildIndices(type: JavaExec) {
  dependsOn copyHelp
  classpath = sourceSets.main.compileClasspath
  main = "com.sun.java.help.search.Indexer"
  workingDir = "${classesDir}/${helpDir}"
  def argDir = "html"
  args = [ argDir ]
  inputs.dir("${workingDir}/${argDir}")

  outputs.dir("${classesDir}/doc")
  outputs.dir("${classesDir}/help")
  outputs.file("${workingDir}/JavaHelpSearch/DOCS")
  outputs.file("${workingDir}/JavaHelpSearch/DOCS.TAB")
  outputs.file("${workingDir}/JavaHelpSearch/OFFSETS")
  outputs.file("${workingDir}/JavaHelpSearch/POSITIONS")
  outputs.file("${workingDir}/JavaHelpSearch/SCHEMA")
  outputs.file("${workingDir}/JavaHelpSearch/TMAP")
}


task compileLinkCheck(type: JavaCompile) {
  options.fork = true
  classpath = files("${jalviewDir}/${utilsDir}")
  destinationDir = file("${jalviewDir}/${utilsDir}")
  source = fileTree(dir: "${jalviewDir}/${utilsDir}", include: ["HelpLinksChecker.java", "BufferedLineReader.java"])

  inputs.file("${jalviewDir}/${utilsDir}/HelpLinksChecker.java")
  inputs.file("${jalviewDir}/${utilsDir}/HelpLinksChecker.java")
  outputs.file("${jalviewDir}/${utilsDir}/HelpLinksChecker.class")
  outputs.file("${jalviewDir}/${utilsDir}/BufferedLineReader.class")
}


task linkCheck(type: JavaExec) {
  dependsOn prepare, compileLinkCheck

  def helpLinksCheckerOutFile = file("${jalviewDir}/${utilsDir}/HelpLinksChecker.out")
  classpath = files("${jalviewDir}/${utilsDir}")
  main = "HelpLinksChecker"
  workingDir = jalviewDir
  def help = "${classesDir}/${helpDir}"
  args = [ "${classesDir}/${helpDir}", "-nointernet" ]

  def outFOS = new FileOutputStream(helpLinksCheckerOutFile, false) // false == don't append
  def errFOS = outFOS
  standardOutput = new org.apache.tools.ant.util.TeeOutputStream(
    outFOS,
    standardOutput)
  errorOutput = new org.apache.tools.ant.util.TeeOutputStream(
    outFOS,
    errorOutput)

  inputs.dir("${classesDir}/${helpDir}")
  outputs.file(helpLinksCheckerOutFile)
}

// import the pubhtmlhelp target
ant.properties.basedir = "${jalviewDir}"
ant.properties.helpBuildDir = "${jalviewDirAbsolutePath}/${classes_dir}/${helpDir}"
ant.importBuild "${utilsDir}/publishHelp.xml"


task cleanPackageDir(type: Delete) {
  doFirst {
    delete fileTree(dir: "${jalviewDir}/${packageDir}", include: "*.jar")
  }
}


jar {
  dependsOn linkCheck
  dependsOn buildIndices
  dependsOn createBuildProperties

  manifest {
    attributes "Main-Class": mainClass,
    "Permissions": "all-permissions",
    "Application-Name": "Jalview Desktop",
    "Codebase": application_codebase
  }

  destinationDir = file("${jalviewDir}/${packageDir}")
  archiveName = rootProject.name+".jar"

  exclude "cache*/**"
  exclude "*.jar"
  exclude "*.jar.*"
  exclude "**/*.jar"
  exclude "**/*.jar.*"

  inputs.dir(classesDir)
  outputs.file("${jalviewDir}/${packageDir}/${archiveName}")
}


task copyJars(type: Copy) {
  from fileTree(dir: classesDir, include: "**/*.jar").files
  into "${jalviewDir}/${packageDir}"
}


// doing a Sync instead of Copy as Copy doesn't deal with "outputs" very well
task syncJars(type: Sync) {
  from fileTree(dir: "${jalviewDir}/${libDistDir}", include: "**/*.jar").files
  into "${jalviewDir}/${packageDir}"
  preserve {
    include jar.archiveName
  }
}


task makeDist {
  group = "build"
  description = "Put all required libraries in dist"
  // order of "cleanPackageDir", "copyJars", "jar" important!
  jar.mustRunAfter cleanPackageDir
  syncJars.mustRunAfter cleanPackageDir
  dependsOn cleanPackageDir
  dependsOn syncJars
  dependsOn jar
  outputs.dir("${jalviewDir}/${packageDir}")
}


task cleanDist {
  dependsOn cleanPackageDir
  dependsOn cleanTest
  dependsOn clean
}

shadowJar {
  group = "distribution"
  if (buildDist) {
    dependsOn makeDist
  }
  from ("${jalviewDir}/${libDistDir}") {
    include("*.jar")
  }
  manifest {
    attributes 'Implementation-Version': JALVIEW_VERSION
  }
  mainClassName = shadowJarMainClass
  mergeServiceFiles()
  classifier = "all-"+JALVIEW_VERSION+"-j"+JAVA_VERSION
  minimize()
}


task getdownWebsite() {
  group = "distribution"
  description = "Create the getdown minimal app folder, and website folder for this version of jalview. Website folder also used for offline app installer"
  if (buildDist) {
    dependsOn makeDist
  }

  def getdownWebsiteResourceFilenames = []
  def getdownTextString = ""
  def getdownResourceDir = getdownResourceDir
  def getdownAppDir = getdownAppDir
  def getdownResourceFilenames = []

  doFirst {
    // clean the getdown website and files dir before creating getdown folders
    delete getdownWebsiteDir
    delete getdownFilesDir

    copy {
      from buildProperties
      rename(build_properties_file, getdown_build_properties)
      into getdownAppDir
    }
    getdownWebsiteResourceFilenames += "${getdown_app_dir}/${getdown_build_properties}"

    // go through properties looking for getdown_txt_...
    def props = project.properties.sort { it.key }
    if (getdown_alt_java_min_version.length() > 0) {
      props.put("getdown_txt_java_min_version", getdown_alt_java_min_version)
    }
    if (getdown_alt_java_max_version.length() > 0) {
      props.put("getdown_txt_java_max_version", getdown_alt_java_max_version)
    }
    props.put("getdown_txt_multi_java_location", getdown_alt_multi_java_location)

    props.put("getdown_txt_appbase", getdown_app_base)
    props.each{ prop, val ->
      if (prop.startsWith("getdown_txt_") && val != null) {
        if (prop.startsWith("getdown_txt_multi_")) {
          def key = prop.substring(18)
          val.split(",").each{ v ->
            def line = "${key} = ${v}\n"
            getdownTextString += line
          }
        } else {
          // file values rationalised
          if (val.indexOf('/') > -1 || prop.startsWith("getdown_txt_resource")) {
            def r = null
            if (val.indexOf('/') == 0) {
              // absolute path
              r = file(val)
            } else if (val.indexOf('/') > 0) {
              // relative path (relative to jalviewDir)
              r = file( "${jalviewDir}/${val}" )
            }
            if (r.exists()) {
              val = "${getdown_resource_dir}/" + r.getName()
              getdownWebsiteResourceFilenames += val
              getdownResourceFilenames += r.getPath()
            }
          }
          if (! prop.startsWith("getdown_txt_resource")) {
            def line = prop.substring(12) + " = ${val}\n"
            getdownTextString += line
          }
        }
      }
    }

    getdownWebsiteResourceFilenames.each{ filename ->
      getdownTextString += "resource = ${filename}\n"
    }
    getdownResourceFilenames.each{ filename ->
      copy {
        from filename
        into getdownResourceDir
      }
    }

    def codeFiles = []
    fileTree(file(packageDir)).each{ f ->
      if (f.isDirectory()) {
        def files = fileTree(dir: f, include: ["*"]).getFiles()
        codeFiles += files
      } else if (f.exists()) {
        codeFiles += f
      }
    }
    codeFiles.sort().each{f ->
      def name = f.getName()
      def line = "code = ${getdown_app_dir}/${name}\n"
      getdownTextString += line
      copy {
        from f.getPath()
        into getdownAppDir
      }
    }

    // NOT USING MODULES YET, EVERYTHING SHOULD BE IN dist
    /*
    if (JAVA_VERSION.equals("11")) {
    def j11libFiles = fileTree(dir: "${jalviewDir}/${j11libDir}", include: ["*.jar"]).getFiles()
    j11libFiles.sort().each{f ->
    def name = f.getName()
    def line = "code = ${getdown_j11lib_dir}/${name}\n"
    getdownTextString += line
    copy {
    from f.getPath()
    into getdownJ11libDir
    }
    }
    }
     */

    // getdown-launcher.jar should not be in main application class path so the main application can move it when updated.  Listed as a resource so it gets updated.
    //getdownTextString += "class = " + file(getdownLauncher).getName() + "\n"
    getdownTextString += "resource = ${getdown_launcher_new}\n"
    getdownTextString += "class = ${mainClass}\n"

    def getdown_txt = file("${getdownWebsiteDir}/getdown.txt")
    getdown_txt.write(getdownTextString)

    def launch_jvl = file("${getdownWebsiteDir}/${getdown_launch_jvl}")
    launch_jvl.write("appbase="+props.get("getdown_txt_appbase"))

    copy {
      from getdownLauncher
      rename(file(getdownLauncher).getName(), getdown_launcher_new)
      into getdownWebsiteDir
    }

    copy {
      from getdownLauncher
      if (file(getdownLauncher).getName() != getdown_launcher) {
        rename(file(getdownLauncher).getName(), getdown_launcher)
      }
      into getdownWebsiteDir
    }

    if (! (CHANNEL.startsWith("ARCHIVE") || CHANNEL.startsWith("DEVELOP"))) {
      copy {
        from getdown_txt
        from getdownLauncher
        from "${getdownWebsiteDir}/${getdown_build_properties}"
        if (file(getdownLauncher).getName() != getdown_launcher) {
          rename(file(getdownLauncher).getName(), getdown_launcher)
        }
        into getdownInstallDir
      }

      copy {
        from getdownInstallDir
        into getdownFilesInstallDir
      }
    }

    copy {
      from getdown_txt
      from launch_jvl
      from getdownLauncher
      from "${getdownWebsiteDir}/${getdown_build_properties}"
      if (file(getdownLauncher).getName() != getdown_launcher) {
        rename(file(getdownLauncher).getName(), getdown_launcher)
      }
      into getdownFilesDir
    }

    copy {
      from getdownResourceDir
      into "${getdownFilesDir}/${getdown_resource_dir}"
    }
  }

  if (buildDist) {
    inputs.dir("${jalviewDir}/${packageDir}")
  }
  outputs.dir(getdownWebsiteDir)
  outputs.dir(getdownFilesDir)
}


task getdownDigest(type: JavaExec) {
  group = "distribution"
  description = "Digest the getdown website folder"
  dependsOn getdownWebsite
  doFirst {
    classpath = files("${getdownWebsiteDir}/${getdown_launcher}")
  }
  main = "com.threerings.getdown.tools.Digester"
  args getdownWebsiteDir
  inputs.dir(getdownWebsiteDir)
  outputs.file("${getdownWebsiteDir}/digest2.txt")
}


task getdown() {
  group = "distribution"
  description = "Create the minimal and full getdown app folder for installers and website and create digest file"
  dependsOn getdownDigest
  doLast {
    if (reportRsyncCommand) {
      def fromDir = getdownWebsiteDir + (getdownWebsiteDir.endsWith('/')?'':'/')
      def toDir = "${getdown_rsync_dest}/${getdownDir}" + (getdownDir.endsWith('/')?'':'/')
      println "LIKELY RSYNC COMMAND:"
      println "mkdir -p '$toDir'\nrsync -avh --delete '$fromDir' '$toDir'"
      if (RUNRSYNC == "true") {
        exec {
          commandLine "mkdir", "-p", toDir
        }
        exec {
          commandLine "rsync", "-avh", "--delete", fromDir, toDir
        }
      }
    }
  }
}


clean {
  doFirst {
    delete getdownWebsiteDir
    delete getdownFilesDir
  }
}


install4j {
  def install4jHomeDir = "/opt/install4j"
  def hostname = "hostname".execute().text.trim()
  if (hostname.equals("jv-bamboo")) {
    install4jHomeDir = System.getProperty("user.home")+"/buildtools/install4j"
  } else if (OperatingSystem.current().isMacOsX()) {
    install4jHomeDir = '/Applications/install4j.app/Contents/Resources/app'
    if (! file(install4jHomeDir).exists()) {
      install4jHomeDir = System.getProperty("user.home")+install4jHomeDir
    }
  } else if (OperatingSystem.current().isLinux()) {
    install4jHomeDir = System.getProperty("user.home")+"/buildtools/install4j"
  }
  installDir = file(install4jHomeDir)
  mediaTypes = Arrays.asList(install4jMediaTypes.split(","))
  if (install4jFaster.equals("true")) {
    faster = true
  }
}


task copyInstall4jTemplate(type: Copy) {
  from (install4jDir) {
    include install4jTemplate
    rename (install4jTemplate, install4jConfFileName)
    filter(ReplaceTokens,
      beginToken: '',
      endToken: '',
      tokens: [
        '9999999999': JAVA_VERSION
      ]
    )
    filter(ReplaceTokens,
      beginToken: '$$',
      endToken: '$$',
      tokens: [
        'JAVA_VERSION': JAVA_VERSION,
        'JAVA_INTEGER_VERSION': JAVA_INTEGER_VERSION,
        'VERSION': JALVIEW_VERSION,
        'MACOS_JAVA_VM_DIR': macosJavaVMDir,
        'MACOS_JAVA_VM_TGZ': macosJavaVMTgz,
        'WINDOWS_JAVA_VM_DIR': windowsJavaVMDir,
        'WINDOWS_JAVA_VM_TGZ': windowsJavaVMTgz,
        'INSTALL4JINFOPLISTFILEASSOCIATIONS': install4jInfoPlistFileAssociations,
        'COPYRIGHT_MESSAGE': install4jCopyrightMessage,
        'MACOS_BUNDLE_ID': install4jMacOSBundleId,
        'GETDOWN_RESOURCE_DIR': getdown_resource_dir,
        'GETDOWN_DIST_DIR': getdown_app_dir,
        'GETDOWN_ALT_DIR': getdown_app_dir_alt,
        'GETDOWN_INSTALL_DIR': getdown_install_dir
      ]
    )
    if (OSX_KEYPASS == "") {
      filter(ReplaceTokens,
        beginToken: 'codeSigning macEnabled="',
        endToken: '"',
        tokens: [
          'true': 'codeSigning macEnabled="false"'
        ]
      )
      filter(ReplaceTokens,
        beginToken: 'runPostProcessor="true" ',
        endToken: 'Processor',
        tokens: [
          'post': 'runPostProcessor="false" postProcessor'
        ]
      )
    }
  }
  into install4jDir
  outputs.files(install4jConfFile)

  doLast {
    // include file associations in installer
    def installerFileAssociationsXml = file("${install4jDir}/${install4jInstallerFileAssociations}").text
    ant.replaceregexp(
      byline: false,
      flags: "s",
      match: '<action name="EXTENSIONS_REPLACED_BY_GRADLE".*?</action>',
      replace: installerFileAssociationsXml,
      file: install4jConfFile
    )
    /*
    // include uninstaller applescript app files in dmg
    def installerDMGUninstallerXml = file("$install4jDir/$install4jDMGUninstallerAppFiles").text
    ant.replaceregexp(
    byline: false,
    flags: "s",
    match: '<file name="UNINSTALL_OLD_JALVIEW_APP_REPLACED_IN_GRADLE" file=.*?>',
    replace: installerDMGUninstallerXml,
    file: install4jConfFile
    )
     */
  }
}


clean {
  doFirst {
    delete install4jConfFile
  }
}


task installers(type: com.install4j.gradle.Install4jTask) {
  group = "distribution"
  description = "Create the install4j installers"
  dependsOn getdown
  dependsOn copyInstall4jTemplate
  projectFile = file(install4jConfFile)
  variables = [majorVersion: version.substring(2, 11), build: 001, OSX_KEYSTORE: OSX_KEYSTORE, JSIGN_SH: JSIGN_SH]
  destination = "${jalviewDir}/${install4jBuildDir}/${JAVA_VERSION}"
  buildSelected = true

  if (OSX_KEYPASS) {
    macKeystorePassword=OSX_KEYPASS
  }

  doFirst {
    println("Using projectFile "+projectFile)
  }

  inputs.dir(getdownWebsiteDir)
  inputs.file(install4jConfFile)
  inputs.dir(macosJavaVMDir)
  inputs.dir(windowsJavaVMDir)
  outputs.dir("${jalviewDir}/${install4jBuildDir}/${JAVA_VERSION}")
}


task sourceDist (type: Tar) {
  
  def VERSION_UNDERSCORES = JALVIEW_VERSION.replaceAll("\\.", "_")
  def outputFileName = "${project.name}_${VERSION_UNDERSCORES}.tar.gz"
  // cater for buildship < 3.1 [3.0.1 is max version in eclipse 2018-09]
  try {
    archiveFileName = outputFileName
  } catch (Exception e) {
    archiveName = outputFileName
  }
  
  compression Compression.GZIP
  
  into project.name

  def EXCLUDE_FILES=["build/*","bin/*","test-output/","test-reports","tests","clover*/*"
  ,".*"
  ,"benchmarking/*"
  ,"**/.*"
  ,"*.class"
  ,"**/*.class","${j11modDir}/**/*.jar","appletlib","**/*locales"
  ,"*locales/**",
  ,"utils/InstallAnywhere"] 
  def PROCESS_FILES=[   "AUTHORS",
  "CITATION",
  "FEATURETODO",
  "JAVA-11-README",
  "FEATURETODO",
  "LICENSE",
  "**/README",
  "RELEASE",
  "THIRDPARTYLIBS","TESTNG",
  "build.gradle",
  "gradle.properties",
  "**/*.java",
  "**/*.html",
  "**/*.xml",
  "**/*.gradle",
  "**/*.groovy",
  "**/*.properties",
  "**/*.perl",
  "**/*.sh"]

  from(jalviewDir) {
    exclude (EXCLUDE_FILES)
    include (PROCESS_FILES)
    filter(ReplaceTokens,
      beginToken: '$$',
      endToken: '$$',
      tokens: [
        'Version-Rel': JALVIEW_VERSION,
        'Year-Rel': getDate("yyyy")
      ]
    )
  }
  from(jalviewDir) {
    exclude (EXCLUDE_FILES)
    exclude (PROCESS_FILES)
    exclude ("appletlib")
    exclude ("**/*locales")
    exclude ("*locales/**")
    exclude ("utils/InstallAnywhere")

    exclude (getdown_files_dir)
    exclude (getdown_website_dir)

    // exluding these as not using jars as modules yet
    exclude ("${j11modDir}/**/*.jar")
  }
  //  from (jalviewDir) {
  //    // explicit includes for stuff that seemed to not get included
  //    include(fileTree("test/**/*."))
  //    exclude(EXCLUDE_FILES)
  //    exclude(PROCESS_FILES)
  //  }
}


task helppages  {
  dependsOn copyHelp
  dependsOn pubhtmlhelp
  
  inputs.dir("${classesDir}/${helpDir}")
  outputs.dir("${buildDir}/distributions/${helpDir}")
}


task j2sSetHeadlessBuild {
  doFirst {
    IN_ECLIPSE = false
  }
}


task jalviewjsSetEclipseWorkspace {
  def propKey = "jalviewjs_eclipse_workspace"
  def propVal = null
  if (project.hasProperty(propKey)) {
    propVal = project.getProperty(propKey)
    if (propVal.startsWith("~/")) {
      propVal = System.getProperty("user.home") + propVal.substring(1)
    }
  }
  def propsFileName = "${jalviewDirAbsolutePath}/${jalviewjsBuildDir}/${jalviewjs_eclipse_workspace_location_file}"
  def propsFile = file(propsFileName)
  def eclipseWsDir = propVal
  def props = new Properties()

  def writeProps = true
  if (( eclipseWsDir == null || !file(eclipseWsDir).exists() ) && propsFile.exists()) {
    def ins = new FileInputStream(propsFileName)
    props.load(ins)
    ins.close()
    if (props.getProperty(propKey, null) != null) {
      eclipseWsDir = props.getProperty(propKey)
      writeProps = false
    }
  }

  if (eclipseWsDir == null || !file(eclipseWsDir).exists()) {
    def tempDir = File.createTempDir()
    eclipseWsDir = tempDir.getAbsolutePath()
    writeProps = true
  }
  eclipseWorkspace = file(eclipseWsDir)

  doFirst {
    // do not run a headless transpile when we claim to be in Eclipse
    if (IN_ECLIPSE) {
      println("Skipping task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
      throw new StopExecutionException("Not running headless transpile whilst IN_ECLIPSE is '${IN_ECLIPSE}'")
    } else {
      println("Running task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
    }

    if (writeProps) {
      props.setProperty(propKey, eclipseWsDir)
      propsFile.parentFile.mkdirs()
      def bytes = new ByteArrayOutputStream()
      props.store(bytes, null)
      def propertiesString = bytes.toString()
      propsFile.text = propertiesString
      print("NEW ")
    } else {
      print("EXISTING ")
    }

    println("ECLIPSE WORKSPACE: "+eclipseWorkspace.getPath())
  }

  //inputs.property(propKey, eclipseWsDir) // eclipseWsDir only gets set once this task runs, so will be out-of-date
  outputs.file(propsFileName)
  outputs.upToDateWhen { eclipseWorkspace.exists() && propsFile.exists() }
}


task jalviewjsEclipsePaths {
  def eclipseProduct

  def eclipseRoot = jalviewjs_eclipse_root
  if (eclipseRoot.startsWith("~/")) {
    eclipseRoot = System.getProperty("user.home") + eclipseRoot.substring(1)
  }
  if (OperatingSystem.current().isMacOsX()) {
    eclipseRoot += "/Eclipse.app"
    eclipseBinary = "${eclipseRoot}/Contents/MacOS/eclipse"
    eclipseProduct = "${eclipseRoot}/Contents/Eclipse/.eclipseproduct"
  } else if (OperatingSystem.current().isWindows()) { // check these paths!!
    if (file("${eclipseRoot}/eclipse").isDirectory() && file("${eclipseRoot}/eclipse/.eclipseproduct").exists()) {
      eclipseRoot += "/eclipse.exe"
    }
    eclipseBinary = "${eclipseRoot}/eclipse"
    eclipseProduct = "${eclipseRoot}/.eclipseproduct"
  } else { // linux or unix
    if (file("${eclipseRoot}/eclipse").isDirectory() && file("${eclipseRoot}/eclipse/.eclipseproduct").exists()) {
      eclipseRoot += "/eclipse"
    }
    eclipseBinary = "${eclipseRoot}/eclipse"
    eclipseProduct = "${eclipseRoot}/.eclipseproduct"
  }

  eclipseVersion = "4.13" // default
  def assumedVersion = true
  if (file(eclipseProduct).exists()) {
    def fis = new FileInputStream(eclipseProduct)
    def props = new Properties()
    props.load(fis)
    eclipseVersion = props.getProperty("version")
    fis.close()
    assumedVersion = false
  }
  
  def propKey = "eclipse_debug"
  eclipseDebug = (project.hasProperty(propKey) && project.getProperty(propKey).equals("true"))

  doFirst {
    // do not run a headless transpile when we claim to be in Eclipse
    if (IN_ECLIPSE) {
      println("Skipping task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
      throw new StopExecutionException("Not running headless transpile whilst IN_ECLIPSE is '${IN_ECLIPSE}'")
    } else {
      println("Running task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
    }

    if (!assumedVersion) {
      println("ECLIPSE VERSION=${eclipseVersion}")
    }
  }
}


task eclipseSetup {
  dependsOn eclipseProject
  dependsOn eclipseClasspath
  dependsOn eclipseJdt
}


// this version (type: Copy) will delete anything in the eclipse dropins folder that isn't in fromDropinsDir
task jalviewjsEclipseCopyDropins(type: Copy) {
  dependsOn jalviewjsEclipsePaths

  def inputFiles = fileTree(dir: "${jalviewDir}/${jalviewjs_eclipse_dropins_dir}", include: "*.jar")
  inputFiles += file("${jalviewDir}/${jalviewjs_j2s_plugin}")
  def outputDir = "${jalviewDir}/${jalviewjsBuildDir}/${jalviewjs_eclipse_tmp_dropins_dir}"

  from inputFiles
  into outputDir
}


// this eclipse -clean doesn't actually work
task jalviewjsCleanEclipse(type: Exec) {
  dependsOn eclipseSetup
  dependsOn jalviewjsEclipsePaths
  dependsOn jalviewjsEclipseCopyDropins

  executable(eclipseBinary)
  args(["-nosplash", "--launcher.suppressErrors", "-data", eclipseWorkspace.getPath(), "-clean", "-console", "-consoleLog"])
  if (eclipseDebug) {
    args += "-debug"
  }
  args += "-l"

  def inputString = """exit
y
"""
  def inputByteStream = new ByteArrayInputStream(inputString.getBytes())
  standardInput = inputByteStream
}

/* not really working yet
jalviewjsEclipseCopyDropins.finalizedBy jalviewjsCleanEclipse
*/


task jalviewjsTransferUnzipSwingJs {
  def file_zip = "${jalviewDir}/${jalviewjs_swingjs_zip}"

  doLast {
    copy {
      from zipTree(file_zip)
      into "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}"
    }
  }

  inputs.file file_zip
  outputs.dir "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}"
}


task jalviewjsTransferUnzipLib {
  def zipFiles = fileTree(dir: "${jalviewDir}/${jalviewjs_libjs_dir}", include: "*.zip")

  doLast {
    zipFiles.each { file_zip -> 
      copy {
        from zipTree(file_zip)
        into "${jalviewDir}/${jalviewjsTransferSiteLibDir}"
      }
    }
  }

  inputs.files zipFiles
  outputs.dir "${jalviewDir}/${jalviewjsTransferSiteLibDir}"
}


task jalviewjsTransferUnzipAllLibs {
  dependsOn jalviewjsTransferUnzipSwingJs
  dependsOn jalviewjsTransferUnzipLib
}


task jalviewjsCreateJ2sSettings(type: WriteProperties) {
  group "JalviewJS"
  description "Create the .j2s file from the j2s.* properties"

  jalviewjsJ2sProps = project.properties.findAll { it.key.startsWith("j2s.") }.sort { it.key }
  def siteDirProperty = "j2s.site.directory"
  def setSiteDir = false
  jalviewjsJ2sProps.each { prop, val ->
    if (val != null) {
      if (prop == siteDirProperty) {
        if (!(val.startsWith('/') || val.startsWith("file://") )) {
          val = "${jalviewDir}/${jalviewjsTransferSiteJsDir}/${val}"
        }
        setSiteDir = true
      }
      property(prop,val)
    }
    if (!setSiteDir) { // default site location, don't override specifically set property
      property(siteDirProperty,"${jalviewDirRelativePath}/${jalviewjsTransferSiteJsDir}")
    }
  }
  outputFile = jalviewjsJ2sSettingsFileName

  if (! IN_ECLIPSE) {
    inputs.properties(jalviewjsJ2sProps)
    outputs.file(jalviewjsJ2sSettingsFileName)
  }
}


task jalviewjsEclipseSetup {
  dependsOn jalviewjsEclipseCopyDropins
  dependsOn jalviewjsSetEclipseWorkspace
  dependsOn jalviewjsCreateJ2sSettings
}


task jalviewjsSyncAllLibs (type: Sync) {
  dependsOn jalviewjsTransferUnzipAllLibs
  def inputFiles = fileTree(dir: "${jalviewDir}/${jalviewjsTransferSiteLibDir}")
  inputFiles += fileTree(dir: "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}")
  def outputDir = "${jalviewDir}/${jalviewjsSiteDir}"

  from inputFiles
  into outputDir
  def outputFiles = []
  rename { filename ->
    outputFiles += "${outputDir}/${filename}"
    null
  }
  preserve {
    include "**"
  }
  outputs.files outputFiles
  inputs.files inputFiles
}


task jalviewjsSyncResources (type: Sync) {
  def inputFiles = fileTree(dir: resourceDir)
  def outputDir = "${jalviewDir}/${jalviewjsSiteDir}/${jalviewjs_j2s_subdir}"

  from inputFiles
  into outputDir
  def outputFiles = []
  rename { filename ->
    outputFiles += "${outputDir}/${filename}"
    null
  }
  preserve {
    include "**"
  }
  outputs.files outputFiles
  inputs.files inputFiles
}


task jalviewjsSyncSiteResources (type: Sync) {
  def inputFiles = fileTree(dir: "${jalviewDir}/${jalviewjs_site_resource_dir}")
  def outputDir = "${jalviewDir}/${jalviewjsSiteDir}"

  from inputFiles
  into outputDir
  def outputFiles = []
  rename { filename ->
    outputFiles += "${outputDir}/${filename}"
    null
  }
  preserve {
    include "**"
  }
  outputs.files outputFiles
  inputs.files inputFiles
}


task jalviewjsSyncBuildProperties (type: Sync) {
  dependsOn createBuildProperties
  def inputFiles = [file(buildProperties)]
  def outputDir = "${jalviewDir}/${jalviewjsSiteDir}/${jalviewjs_j2s_subdir}"

  from inputFiles
  into outputDir
  def outputFiles = []
  rename { filename ->
    outputFiles += "${outputDir}/${filename}"
    null
  }
  preserve {
    include "**"
  }
  outputs.files outputFiles
  inputs.files inputFiles
}


task jalviewjsProjectImport(type: Exec) {
  dependsOn eclipseSetup
  dependsOn jalviewjsEclipsePaths
  dependsOn jalviewjsEclipseSetup

  doFirst {
    // do not run a headless import when we claim to be in Eclipse
    if (IN_ECLIPSE) {
      println("Skipping task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
      throw new StopExecutionException("Not running headless import whilst IN_ECLIPSE is '${IN_ECLIPSE}'")
    } else {
      println("Running task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
    }
  }

  //def projdir = eclipseWorkspace.getPath()+"/.metadata/.plugins/org.eclipse.core.resources/.projects/jalview/org.eclipse.jdt.core"
  def projdir = eclipseWorkspace.getPath()+"/.metadata/.plugins/org.eclipse.core.resources/.projects/jalview"
  executable(eclipseBinary)
  args(["-nosplash", "--launcher.suppressErrors", "-application", "com.seeq.eclipse.importprojects.headlessimport", "-data", eclipseWorkspace.getPath(), "-import", jalviewDirAbsolutePath])
  if (eclipseDebug) {
    args += "-debug"
  }
  args += [ "--launcher.appendVmargs", "-vmargs", "-Dorg.eclipse.equinox.p2.reconciler.dropins.directory=${jalviewDirAbsolutePath}/${jalviewjsBuildDir}/${jalviewjs_eclipse_tmp_dropins_dir}" ]
  if (!IN_ECLIPSE) {
    args += [ "-D${j2sHeadlessBuildProperty}=true" ]
  }

  inputs.file("${jalviewDir}/.project")
  outputs.upToDateWhen { 
    file(projdir).exists()
  }
}


task jalviewjsTranspile(type: Exec) {
  dependsOn jalviewjsEclipseSetup 
  dependsOn jalviewjsProjectImport
  dependsOn jalviewjsEclipsePaths

  doFirst {
    // do not run a headless transpile when we claim to be in Eclipse
    if (IN_ECLIPSE) {
      println("Skipping task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
      throw new StopExecutionException("Not running headless transpile whilst IN_ECLIPSE is '${IN_ECLIPSE}'")
    } else {
      println("Running task ${name} as IN_ECLIPSE=${IN_ECLIPSE}")
    }
  }

  executable(eclipseBinary)
  args(["-nosplash", "--launcher.suppressErrors", "-application", "org.eclipse.jdt.apt.core.aptBuild", "-data", eclipseWorkspace, "-${jalviewjs_eclipse_build_arg}", eclipse_project_name ])
  if (eclipseDebug) {
    args += "-debug"
  }
  args += [ "--launcher.appendVmargs", "-vmargs", "-Dorg.eclipse.equinox.p2.reconciler.dropins.directory=${jalviewDirAbsolutePath}/${jalviewjsBuildDir}/${jalviewjs_eclipse_tmp_dropins_dir}" ]
  if (!IN_ECLIPSE) {
    args += [ "-D${j2sHeadlessBuildProperty}=true" ]
  }

  def stdout
  def stderr
  doFirst {
    stdout = new ByteArrayOutputStream()
    stderr = new ByteArrayOutputStream()

    def logOutFileName = "${jalviewDirAbsolutePath}/${jalviewjsBuildDir}/${jalviewjs_j2s_transpile_stdout}"
    def logOutFile = file(logOutFileName)
    logOutFile.createNewFile()
    logOutFile.text = """ROOT: ${jalviewjs_eclipse_root}
BINARY: ${eclipseBinary}
VERSION: ${eclipseVersion}
WORKSPACE: ${eclipseWorkspace}
DEBUG: ${eclipseDebug}
----
"""
    def logOutFOS = new FileOutputStream(logOutFile, true) // true == append
    // combine stdout and stderr
    def logErrFOS = logOutFOS

    if (jalviewjs_j2s_to_console.equals("true")) {
      standardOutput = new org.apache.tools.ant.util.TeeOutputStream(
        new org.apache.tools.ant.util.TeeOutputStream(
          logOutFOS,
          stdout),
        standardOutput)
      errorOutput = new org.apache.tools.ant.util.TeeOutputStream(
        new org.apache.tools.ant.util.TeeOutputStream(
          logErrFOS,
          stderr),
        errorOutput)
    } else {
      standardOutput = new org.apache.tools.ant.util.TeeOutputStream(
        logOutFOS,
        stdout)
      errorOutput = new org.apache.tools.ant.util.TeeOutputStream(
        logErrFOS,
        stderr)
    }
  }

  doLast {
    if (stdout.toString().contains("Error processing ")) {
      // j2s did not complete transpile
      //throw new TaskExecutionException("Error during transpilation:\n${stderr}\nSee eclipse transpile log file '${jalviewDir}/${jalviewjsBuildDir}/${jalviewjs_j2s_transpile_stdout}'")
      throw new GradleException("Error during transpilation:\n${stderr}\nSee eclipse transpile log file '${jalviewDir}/${jalviewjsBuildDir}/${jalviewjs_j2s_transpile_stdout}'")
    }
  }

  inputs.dir("${jalviewDir}/${sourceDir}")
  outputs.dir("${jalviewDir}/${jalviewjsTransferSiteJsDir}")
  outputs.upToDateWhen( { file("${jalviewDir}/${jalviewjsTransferSiteJsDir}${jalviewjs_server_resource}").exists() } )
}


def jalviewjsCallCore(String name, FileCollection list, String prefixFile, String suffixFile, String jsfile, String zjsfile, File logOutFile, Boolean logOutConsole) {

  def stdout = new ByteArrayOutputStream()
  def stderr = new ByteArrayOutputStream()

  def coreFile = file(jsfile)
  def msg = ""
  msg = "Creating core for ${name}...\nGenerating ${jsfile}"
  println(msg)
  logOutFile.createNewFile()
  logOutFile.append(msg+"\n")

  def coreTop = file(prefixFile)
  def coreBottom = file(suffixFile)
  coreFile.getParentFile().mkdirs()
  coreFile.createNewFile()
  coreFile.write( coreTop.text )
  list.each {
    f ->
    if (f.exists()) {
      def t = f.text
      t.replaceAll("Clazz\\.([^_])","Clazz_${1}")
      coreFile.append( t )
    } else {
      msg = "...file '"+f.getPath()+"' does not exist, skipping"
      println(msg)
      logOutFile.append(msg+"\n")
    }
  }
  coreFile.append( coreBottom.text )

  msg = "Generating ${zjsfile}"
  println(msg)
  logOutFile.append(msg+"\n")
  def logOutFOS = new FileOutputStream(logOutFile, true) // true == append
  def logErrFOS = logOutFOS

  javaexec {
    classpath = files(["${jalviewDir}/tools/closure_compiler.jar"])
    args = [ "--js", jsfile, "--js_output_file", zjsfile ]
    maxHeapSize = "2g"

    msg = "\nRunning '"+commandLine.join(' ')+"'\n"
    println(msg)
    logOutFile.append(msg+"\n")

    if (logOutConsole) {
      standardOutput = new org.apache.tools.ant.util.TeeOutputStream(
        new org.apache.tools.ant.util.TeeOutputStream(
          logOutFOS,
          stdout),
        standardOutput)
        errorOutput = new org.apache.tools.ant.util.TeeOutputStream(
          new org.apache.tools.ant.util.TeeOutputStream(
            logErrFOS,
            stderr),
          errorOutput)
    } else {
      standardOutput = new org.apache.tools.ant.util.TeeOutputStream(
        logOutFOS,
        stdout)
        errorOutput = new org.apache.tools.ant.util.TeeOutputStream(
          logErrFOS,
          stderr)
    }
  }
  msg = "--"
  println(msg)
  logOutFile.append(msg+"\n")
}


task jalviewjsBuildAllCores {
  group "JalviewJS"
  description "Build the core js lib closures listed in the classlists dir"
  dependsOn jalviewjsTranspile
  dependsOn jalviewjsTransferUnzipSwingJs

  def j2sDir = "${jalviewDir}/${jalviewjsTransferSiteJsDir}/${jalviewjs_j2s_subdir}"
  def swingJ2sDir = "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}/${jalviewjs_j2s_subdir}"
  def libJ2sDir = "${jalviewDir}/${jalviewjsTransferSiteLibDir}/${jalviewjs_j2s_subdir}"
  def jsDir = "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}/${jalviewjs_js_subdir}"
  def outputDir = "${jalviewDir}/${jalviewjsTransferSiteCoreDir}/${jalviewjs_j2s_subdir}/core"
  def prefixFile = "${jsDir}/core/coretop2.js"
  def suffixFile = "${jsDir}/core/corebottom2.js"

  inputs.file prefixFile
  inputs.file suffixFile

  def classlistFiles = []
  // add the classlists found int the jalviewjs_classlists_dir
  fileTree(dir: "${jalviewDir}/${jalviewjs_classlists_dir}", include: "*.txt").each {
    file ->
    def name = file.getName() - ".txt"
    classlistFiles += [
      'file': file,
      'name': name
    ]
  }

  // _jmol and _jalview cores. Add any other peculiar classlist.txt files here
  //classlistFiles += [ 'file': file("${jalviewDir}/${jalviewjs_classlist_jmol}"), 'name': "_jvjmol" ]
  classlistFiles += [ 'file': file("${jalviewDir}/${jalviewjs_classlist_jalview}"), 'name': jalviewjsJalviewCoreName ]

  jalviewjsCoreClasslists = []

  classlistFiles.each {
    hash ->

    def file = hash['file']
    if (! file.exists()) {
      //println("...classlist file '"+file.getPath()+"' does not exist, skipping")
      return false // this is a "continue" in groovy .each closure
    }
    def name = hash['name']
    if (name == null) {
      name = file.getName() - ".txt"
    }

    def filelist = []
    file.eachLine {
      line ->
        filelist += line
    }
    def list = fileTree(dir: j2sDir, includes: filelist)

    def jsfile = "${outputDir}/core${name}.js"
    def zjsfile = "${outputDir}/core${name}.z.js"

    jalviewjsCoreClasslists += [
      'jsfile': jsfile,
      'zjsfile': zjsfile,
      'list': list,
      'name': name
    ]

    inputs.file(file)
    inputs.files(list)
    outputs.file(jsfile)
    outputs.file(zjsfile)
  }
  
  // _stevesoft core. add any cores without a classlist here (and the inputs and outputs)
  def stevesoftClasslistName = "_stevesoft"
  def stevesoftClasslist = [
    'jsfile': "${outputDir}/core${stevesoftClasslistName}.js",
    'zjsfile': "${outputDir}/core${stevesoftClasslistName}.z.js",
    'list': fileTree(dir: j2sDir, include: "com/stevesoft/pat/**/*.js"),
    'name': stevesoftClasslistName
  ]
  jalviewjsCoreClasslists += stevesoftClasslist
  inputs.files(stevesoftClasslist['list'])
  outputs.file(stevesoftClasslist['jsfile'])
  outputs.file(stevesoftClasslist['zjsfile'])

  // _all core
  def allClasslistName = "_all"
  def allJsFiles = fileTree(dir: j2sDir, include: "**/*.js")
  allJsFiles += fileTree(
    dir: libJ2sDir,
    include: "**/*.js",
    excludes: [
      // these exlusions are files that the closure-compiler produces errors for. Should fix them
      "**/org/jmol/jvxl/readers/IsoIntersectFileReader.js",
      "**/org/jmol/export/JSExporter.js"
    ]
  )
  allJsFiles += fileTree(
    dir: swingJ2sDir,
    include: "**/*.js",
    excludes: [
      // these exlusions are files that the closure-compiler produces errors for. Should fix them
      "**/sun/misc/Unsafe.js",
      "**/swingjs/jquery/jquery-editable-select.js",
      "**/swingjs/jquery/j2sComboBox.js",
      "**/sun/misc/FloatingDecimal.js"
    ]
  )
  def allClasslist = [
    'jsfile': "${outputDir}/core${allClasslistName}.js",
    'zjsfile': "${outputDir}/core${allClasslistName}.z.js",
    'list': allJsFiles,
    'name': allClasslistName
  ]
  // not including this version of "all" core at the moment
  //jalviewjsCoreClasslists += allClasslist
  inputs.files(allClasslist['list'])
  outputs.file(allClasslist['jsfile'])
  outputs.file(allClasslist['zjsfile'])

  doFirst {
    def logOutFile = file("${jalviewDirAbsolutePath}/${jalviewjsBuildDir}/${jalviewjs_j2s_closure_stdout}")
    logOutFile.getParentFile().mkdirs()
    logOutFile.createNewFile()
    logOutFile.write(getDate("yyyy-MM-dd HH:mm:ss")+" jalviewjsBuildAllCores\n----\n")

    jalviewjsCoreClasslists.each {
      jalviewjsCallCore(it.name, it.list, prefixFile, suffixFile, it.jsfile, it.zjsfile, logOutFile, jalviewjs_j2s_to_console.equals("true"))
    }
  }

}


def jalviewjsPublishCoreTemplate(String coreName, String templateName, File inputFile, String outputFile) {
  copy {
    from inputFile
    into file(outputFile).getParentFile()
    rename { filename ->
      if (filename.equals(inputFile.getName())) {
        return file(outputFile).getName()
      }
      return null
    }
    filter(ReplaceTokens,
      beginToken: '_',
      endToken: '_',
      tokens: [
        'MAIN': '"'+mainClass+'"',
        'CODE': "null",
        'NAME': jalviewjsJalviewTemplateName+" [core ${coreName}]",
        'COREKEY': jalviewjs_core_key,
        'CORENAME': coreName
      ]
    )
  }
}


task jalviewjsPublishCoreTemplates {
  dependsOn jalviewjsBuildAllCores
  def inputFileName = "${jalviewDir}/${j2s_coretemplate_html}"
  def inputFile = file(inputFileName)
  def outputDir = "${jalviewDir}/${jalviewjsTransferSiteCoreDir}"

  def outputFiles = []
  jalviewjsCoreClasslists.each { cl ->
    def outputFile = "${outputDir}/${jalviewjsJalviewTemplateName}_${cl.name}.html"
    cl['outputfile'] = outputFile
    outputFiles += outputFile
  }

  doFirst {
    jalviewjsCoreClasslists.each { cl ->
      jalviewjsPublishCoreTemplate(cl.name, jalviewjsJalviewTemplateName, inputFile, cl.outputfile)
    }
  }
  inputs.file(inputFile)
  outputs.files(outputFiles)
}


task jalviewjsSyncCore (type: Sync) {
  dependsOn jalviewjsBuildAllCores
  dependsOn jalviewjsPublishCoreTemplates
  def inputFiles = fileTree(dir: "${jalviewDir}/${jalviewjsTransferSiteCoreDir}")
  def outputDir = "${jalviewDir}/${jalviewjsSiteDir}"

  from inputFiles
  into outputDir
  def outputFiles = []
  rename { filename ->
    outputFiles += "${outputDir}/${filename}"
    null
  }
  preserve {
    include "**"
  }
  outputs.files outputFiles
  inputs.files inputFiles
}


// this Copy version of TransferSiteJs will delete anything else in the target dir
task jalviewjsCopyTransferSiteJs(type: Copy) {
  dependsOn jalviewjsTranspile
  from "${jalviewDir}/${jalviewjsTransferSiteJsDir}"
  into "${jalviewDir}/${jalviewjsSiteDir}"
}


// this Sync version of TransferSite is used by buildship to keep the website automatically up to date when a file changes
task jalviewjsSyncTransferSiteJs(type: Sync) {
  from "${jalviewDir}/${jalviewjsTransferSiteJsDir}"
  include "**/*.*"
  into "${jalviewDir}/${jalviewjsSiteDir}"
  preserve {
    include "**"
  }
}


jalviewjsSyncAllLibs.mustRunAfter jalviewjsCopyTransferSiteJs
jalviewjsSyncResources.mustRunAfter jalviewjsCopyTransferSiteJs
jalviewjsSyncSiteResources.mustRunAfter jalviewjsCopyTransferSiteJs
jalviewjsSyncBuildProperties.mustRunAfter jalviewjsCopyTransferSiteJs

jalviewjsSyncAllLibs.mustRunAfter jalviewjsSyncTransferSiteJs
jalviewjsSyncResources.mustRunAfter jalviewjsSyncTransferSiteJs
jalviewjsSyncSiteResources.mustRunAfter jalviewjsSyncTransferSiteJs
jalviewjsSyncBuildProperties.mustRunAfter jalviewjsSyncTransferSiteJs


task jalviewjsPrepareSite {
  group "JalviewJS"
  description "Prepares the website folder including unzipping files and copying resources"
  dependsOn jalviewjsSyncAllLibs
  dependsOn jalviewjsSyncResources
  dependsOn jalviewjsSyncSiteResources
  dependsOn jalviewjsSyncBuildProperties
  dependsOn jalviewjsSyncCore
}


task jalviewjsBuildSite {
  group "JalviewJS"
  description "Builds the whole website including transpiled code"
  dependsOn jalviewjsCopyTransferSiteJs
  dependsOn jalviewjsPrepareSite
}


task cleanJalviewjsTransferSite {
  doFirst {
    delete "${jalviewDir}/${jalviewjsTransferSiteJsDir}"
    delete "${jalviewDir}/${jalviewjsTransferSiteLibDir}"
    delete "${jalviewDir}/${jalviewjsTransferSiteSwingJsDir}"
    delete "${jalviewDir}/${jalviewjsTransferSiteCoreDir}"
  }
}


task cleanJalviewjsSite {
  dependsOn cleanJalviewjsTransferSite
  doFirst {
    delete "${jalviewDir}/${jalviewjsSiteDir}"
  }
}


task jalviewjsSiteTar(type: Tar) {
  group "JalviewJS"
  description "Creates a tar.gz file for the website"
  dependsOn jalviewjsBuildSite
  def outputFilename = "jalviewjs-site-${JALVIEW_VERSION}.tar.gz"
  try {
    archiveFileName = outputFilename
  } catch (Exception e) {
    archiveName = outputFilename
  }

  compression Compression.GZIP

  from "${jalviewDir}/${jalviewjsSiteDir}"
  into jalviewjs_site_dir // this is inside the tar file

  inputs.dir("${jalviewDir}/${jalviewjsSiteDir}")
}


task jalviewjsServer {
  group "JalviewJS"
  def filename = "jalviewjsTest.html"
  description "Starts a webserver on localhost to test the website. See ${filename} to access local site on most recently used port."
  def htmlFile = "${jalviewDirAbsolutePath}/${filename}"
  doLast {

    SimpleHttpFileServerFactory factory = new SimpleHttpFileServerFactory()
    def port = Integer.valueOf(jalviewjs_server_port)
    def start = port
    def running = false
    def url
    def jalviewjsServer
    while(port < start+1000 && !running) {
      try {
        def doc_root = new File("${jalviewDirAbsolutePath}/${jalviewjsSiteDir}")
        jalviewjsServer = factory.start(doc_root, port)
        running = true
        url = jalviewjsServer.getResourceUrl(jalviewjs_server_resource)
        println("SERVER STARTED with document root ${doc_root}.")
        println("Go to "+url+" . Run  gradle --stop  to stop (kills all gradle daemons).")
        println("For debug: "+url+"?j2sdebug")
        println("For verbose: "+url+"?j2sverbose")
      } catch (Exception e) {
        port++;
      }
    }
    def htmlText = """
      <p><a href="${url}">JalviewJS Test. &lt;${url}&gt;</a></p>
      <p><a href="${url}?j2sdebug">JalviewJS Test with debug. &lt;${url}?j2sdebug&gt;</a></p>
      <p><a href="${url}?j2sverbose">JalviewJS Test with verbose. &lt;${url}?j2sdebug&gt;</a></p>
      """
    jalviewjsCoreClasslists.each { cl ->
      def urlcore = jalviewjsServer.getResourceUrl(file(cl.outputfile).getName())
      htmlText += """
      <p><a href="${urlcore}">${jalviewjsJalviewTemplateName} [core ${cl.name}]. &lt;${urlcore}&gt;</a></p>
      """
      println("For core ${cl.name}: "+urlcore)
    }

    file(htmlFile).text = htmlText
  }

  outputs.file(htmlFile)
  outputs.upToDateWhen({false})
}


task cleanJalviewjsAll {
  group "JalviewJS"
  description "Delete all configuration and build artifacts to do with JalviewJS build"
  dependsOn cleanJalviewjsSite
  dependsOn jalviewjsEclipsePaths
  
  doFirst {
    delete "${jalviewDir}/${jalviewjsBuildDir}"
    delete "${jalviewDir}/${eclipse_bin_dir}"
    if (eclipseWorkspace != null && file(eclipseWorkspace.getAbsolutePath()+"/.metadata").exists()) {
      delete file(eclipseWorkspace.getAbsolutePath()+"/.metadata")
    }
    delete "${jalviewDir}/${jalviewjs_j2s_settings}"
  }

  outputs.upToDateWhen( { false } )
}


task jalviewjsIDE_checkJ2sPlugin {
  group "00 JalviewJS in Eclipse"
  description "Compare the swingjs/net.sf.j2s.core.jar file with the Eclipse IDE's plugin version (found in the 'dropins' dir)"

  doFirst {
    def j2sPlugin = string("${jalviewDir}/${jalviewjs_j2s_plugin}")
    def j2sPluginFile = file(j2sPlugin)
    def copyPlugin = jalviewjs_eclipseIDE_auto_copy_j2s_plugin == "true"
    def eclipseHome = System.properties["eclipse.home.location"]
    def doCopy = false
    if (eclipseHome == null || ! IN_ECLIPSE) {
      throw new StopExecutionException("Cannot find running Eclipse home from System.properties['eclipse.home.location']. Skipping J2S Plugin Check.")
    }
    def eclipseJ2sPlugin = "${eclipseHome}/dropins/${j2sPluginFile.getName()}"
    def eclipseJ2sPluginFile = file(eclipseJ2sPlugin)
    if (!eclipseJ2sPluginFile.exists()) {
      def msg = "Eclipse J2S Plugin is not installed"
      println(msg)
      if (! copyPlugin) {
        throw new GradleException(msg)
      }
      doCopy = true
    }

    def digest = MessageDigest.getInstance("MD5")

    digest.update(j2sPluginFile.text.bytes)
    def j2sPluginMd5 = new BigInteger(1, digest.digest()).toString(16).padLeft(32, '0')

    digest.update(eclipseJ2sPluginFile.text.bytes)
    def eclipseJ2sPluginMd5 = new BigInteger(1, digest.digest()).toString(16).padLeft(32, '0')
     
    if (j2sPluginMd5 != eclipseJ2sPluginMd5) {
      def msg = "WARNING! Eclipse J2S Plugin '${eclipseJ2sPlugin}' is different to this commit's version '${j2sPlugin}'"
      println(msg)
      if (! copyPlugin) {
        throw new StopExecutionException(msg)
      }
      doCopy = true
    }

    if (doCopy) {
      def msg = "WARNING! Auto-copying this commit's j2s plugin version '${j2sPlugin}' to Eclipse J2S Plugin '${eclipseJ2sPlugin}'\n         May require an Eclipse restart"
      println(msg)
      copy {
        from j2sPlugin
        eclipseJ2sPluginFile.getParentFile().mkdirs()
        into eclipseJ2sPluginFile.getParent()
      }
    } else {
      def msg = "Eclipse J2S Plugin is the same as '${j2sPlugin}'"
      println(msg)
    }
  }
}


task jalviewjsIDE_j2sFile {
  group "00 JalviewJS in Eclipse"
  description "Creates the .j2s file"
  dependsOn jalviewjsCreateJ2sSettings
}


task jalviewjsIDE_SyncCore {
  group "00 JalviewJS in Eclipse"
  description "Build the core js lib closures listed in the classlists dir and publish core html from template"
  dependsOn jalviewjsSyncCore
}


task jalviewjsIDE_SyncSiteAll {
  dependsOn jalviewjsSyncAllLibs
  dependsOn jalviewjsSyncResources
  dependsOn jalviewjsSyncSiteResources
  dependsOn jalviewjsSyncBuildProperties
}


cleanJalviewjsTransferSite.mustRunAfter jalviewjsIDE_SyncSiteAll


task jalviewjsIDE_PrepareSite {
  group "00 JalviewJS in Eclipse"
  description "Sync libs and resources to site dir, but not closure cores"

  dependsOn jalviewjsIDE_SyncSiteAll
  dependsOn cleanJalviewjsTransferSite
}


task jalviewjsIDE_AssembleSite {
  group "00 JalviewJS in Eclipse"
  description "Assembles unzipped supporting zipfiles, resources, site resources and closure cores into the Eclipse transpiled site"
  dependsOn jalviewjsPrepareSite
}


task jalviewjsIDE_SiteClean {
  group "00 JalviewJS in Eclipse"
  description "Deletes the Eclipse transpiled site"
  dependsOn cleanJalviewjsSite
}


task jalviewjsIDE_Server {
  group "00 JalviewJS in Eclipse"
  description "Starts a webserver on localhost to test the website"
  dependsOn jalviewjsServer
}


// buildship runs this at import or gradle refresh
task eclipseSynchronizationTask {
  //dependsOn eclipseSetup
  dependsOn createBuildProperties
  if (J2S_ENABLED) {
    dependsOn jalviewjsIDE_j2sFile
    dependsOn jalviewjsIDE_checkJ2sPlugin
    dependsOn jalviewjsIDE_PrepareSite
  }
}


// buildship runs this at build time or project refresh
task eclipseAutoBuildTask {
  //dependsOn jalviewjsIDE_checkJ2sPlugin
  //dependsOn jalviewjsIDE_PrepareSite
}








task jalviewjs {
  group "JalviewJS"
  description "Build the site"
  dependsOn jalviewjsBuildSite
}