build.gradle

   1 import org.apache.tools.ant.filters.ReplaceTokens
   2 //import org.apache.tools.ant.filters.ReplaceRegexp
   3 import org.gradle.internal.os.OperatingSystem
   4 import org.gradle.plugins.ide.eclipse.model.*
   5
   6
   7 import groovy.transform.ExternalizeMethods
   8
   9 buildscript {
  10   dependencies {
  11     classpath 'org.openclover:clover:4.3.1'
  12     classpath 'org.apache.commons:commons-compress:1.18'
  13   }
  14 }
  15
  16 plugins {
  17   id 'java'
  18   id 'application'
  19   id 'eclipse'
  20   id 'com.github.johnrengelman.shadow' version '4.0.3'
  21   id 'com.install4j.gradle' version '7.0.9'
  22 }
  23
  24 repositories {
  25   jcenter()
  26   mavenCentral()
  27   mavenLocal()
  28   flatDir {
  29     dirs gradlePluginsDir
  30   }
  31 }
  32
  33 mainClassName = launcherClass
  34 def cloverInstrDir = file("$buildDir/$cloverSourcesInstrDir")
  35 def classes = "$jalviewDir/$classesDir"
  36
  37 if (clover.equals("true")) {
  38   use_clover = true
  39   classes = "$buildDir/$cloverClassesDir"
  40 } else {
  41   use_clover = false
  42   classes = "$jalviewDir/$classesDir"
  43 }
  44
  45 // configure classpath/args for j8/j11 compilation
  46
  47 def jalviewDirAbsolutePath = file(jalviewDir).getAbsolutePath()
  48 def libDir
  49 def libDistDir
  50 def compile_source_compatibility
  51 def compile_target_compatibility
  52
  53 ext {
  54   // where the getdown channel will be built.
  55   // TODO: consider allowing this expression to  be overridden by -P arg
  56   getdownWebsiteDir = jalviewDir + '/' + getdown_website_dir + '/' + JAVA_VERSION
  57   getdownAppDir = getdownWebsiteDir + '/' + getdown_app_dir
  58   getdownJ11libDir = getdownWebsiteDir + '/' + getdown_j11lib_dir
  59   getdownResourceDir = getdownWebsiteDir + '/' + getdown_resource_dir
  60   getdownLauncher = jalviewDir + '/' + getdown_launcher
  61   getdownFilesDir = jalviewDir + '/' + getdown_files_dir + '/' + JAVA_VERSION + '/'
  62   getdown_app_base = getdown_channel_base+"/"+getdown_channel_name+"/"+JAVA_VERSION+"/"
  63   modules_compileClasspath = fileTree(dir: "$jalviewDir/$j11modDir", include: ["*.jar"])
  64   modules_runtimeClasspath = modules_compileClasspath
  65   gitHash = ""
  66   gitBranch = ""
  67 }
  68
  69 def JAVA_INTEGER_VERSION
  70 def additional_compiler_args = []
  71 // these are getdown.txt properties defined dependent on the JAVA_VERSION
  72 def getdown_alt_java_min_version
  73 // this property is assigned below and expanded to multiple lines in the getdown task
  74 def getdown_alt_multi_java_location
  75 if (JAVA_VERSION.equals("1.8")) {
  76   JAVA_INTEGER_VERSION = "8"
  77   libDir = j11libDir
  78   libDistDir = j8libDir
  79   compile_source_compatibility = 1.8
  80   compile_target_compatibility = 1.8
  81   getdown_alt_java_min_version = getdown_alt_java8_min_version
  82   getdown_alt_multi_java_location = getdown_alt_java8_txt_multi_java_location
  83 } else if (JAVA_VERSION.equals("11")) {
  84   JAVA_INTEGER_VERSION = "11"
  85   libDir = j11libDir
  86   libDistDir = j11libDir
  87   compile_source_compatibility = 11
  88   compile_target_compatibility = 11
  89   getdown_alt_java_min_version = getdown_alt_java11_min_version
  90   getdown_alt_multi_java_location = getdown_alt_java11_txt_multi_java_location
  91   additional_compiler_args += [
  92     '--module-path', ext.modules_compileClasspath.asPath,
  93     '--add-modules', j11modules
  94   ]
  95 } else {
  96   throw new GradleException("JAVA_VERSION=$JAVA_VERSION not currently supported by Jalview")
  97 }
  98
  99 sourceSets {
 100
 101   main {
 102     java {
 103       srcDirs "$jalviewDir/$sourceDir"
 104       outputDir = file("$classes")
 105     }
 106
 107     resources {
 108       srcDirs "$jalviewDir/$resourceDir"
 109       srcDirs "$jalviewDir/$libDistDir"
 110     }
 111
 112     jar.destinationDir = file("$jalviewDir/$packageDir")
 113
 114     compileClasspath = files(sourceSets.main.java.outputDir)
 115     compileClasspath += fileTree(dir: "$jalviewDir/$libDir", include: ["*.jar"])
 116
 117     runtimeClasspath = compileClasspath
 118   }
 119   clover {
 120     java {
 121       srcDirs = [ cloverInstrDir ]
 122       outputDir = file("${buildDir}/${cloverClassesDir}")
 123     }
 124
 125     resources {
 126       srcDirs = sourceSets.main.resources.srcDirs
 127     }
 128     compileClasspath = configurations.cloverRuntime + files( sourceSets.clover.java.outputDir )
 129     compileClasspath += files(sourceSets.main.java.outputDir)
 130     compileClasspath += sourceSets.main.compileClasspath
 131     compileClasspath += fileTree(dir: "$jalviewDir/$utilsDir", include: ["**/*.jar"])
 132     compileClasspath += fileTree(dir: "$jalviewDir/$libDir", include: ["*.jar"])
 133
 134     runtimeClasspath = compileClasspath
 135   }
 136
 137   test {
 138     java {
 139       srcDirs "$jalviewDir/$testSourceDir"
 140       outputDir = file("$jalviewDir/$testOutputDir")
 141     }
 142
 143     resources {
 144       srcDirs = sourceSets.main.resources.srcDirs
 145     }
 146
 147     compileClasspath = files( sourceSets.test.java.outputDir )
 148
 149     if (use_clover) {
 150       compileClasspath += sourceSets.clover.compileClasspath
 151     } else {
 152       compileClasspath += files(sourceSets.main.java.outputDir)
 153     }
 154     //compileClasspath += sourceSets.main.compileClasspath
 155     //compileClasspath += files( sourceSets.main.resources.srcDirs)
 156     compileClasspath += fileTree(dir: "$jalviewDir/$utilsDir", include: ["**/*.jar"])
 157     compileClasspath += fileTree(dir: "$jalviewDir/$libDir", include: ["*.jar"])
 158
 159     runtimeClasspath = compileClasspath
 160   }
 161 }
 162
 163 // clover bits
 164 dependencies {
 165   if (use_clover) {
 166     cloverCompile 'org.openclover:clover:4.3.1'
 167     testCompile 'org.openclover:clover:4.3.1'
 168   }
 169 }
 170
 171 configurations {
 172   cloverRuntime
 173   cloverRuntime.extendsFrom cloverCompile
 174 }
 175
 176 eclipse {
 177   project {
 178     name = "Jalview with gradle build"
 179
 180     natures 'org.eclipse.jdt.core.javanature',
 181         'org.eclipse.jdt.groovy.core.groovyNature',
 182         'org.eclipse.buildship.core.gradleprojectnature'
 183
 184     buildCommand 'org.eclipse.jdt.core.javabuilder'
 185     buildCommand 'org.eclipse.buildship.core.gradleprojectbuilder'
 186   }
 187
 188   classpath {
 189     //defaultOutputDir = sourceSets.main.java.outputDir
 190     def removeThese = []
 191     configurations.each{ if (it.isCanBeResolved()) {
 192         removeThese += it
 193       }
 194     }
 195
 196     minusConfigurations += removeThese
 197     plusConfigurations = [ ]
 198     file {
 199
 200       whenMerged { cp ->
 201         def removeTheseToo = []
 202         HashMap<String, Boolean> addedSrcPath = new HashMap<>();
 203         cp.entries.each { entry ->
 204           if (entry.kind == 'src') {
 205             if (addedSrcPath.getAt(entry.path) || !(entry.path == "src" || entry.path == "test")) {
 206               removeTheseToo += entry
 207             } else {
 208               addedSrcPath.putAt(entry.path, true)
 209             }
 210           }
 211         }
 212         cp.entries.removeAll(removeTheseToo)
 213
 214         cp.entries += new Output("bin/main")
 215         cp.entries += new Library(fileReference(helpParentDir))
 216         cp.entries += new Library(fileReference(resourceDir))
 217
 218         HashMap<String, Boolean> addedLibPath = new HashMap<>();
 219         def allPaths = sourceSets.test.compileClasspath + sourceSets.main.compileClasspath
 220         sourceSets.main.compileClasspath.each{
 221           //if ((it.isDirectory() || ! it.exists()) && ! (it.equals(sourceSets.main.java.outputDir))) {
 222           //no longer want to add outputDir as eclipse is using its own output dir in bin/main
 223           if (it.isDirectory() || ! it.exists()) {
 224             // don't add dirs to classpath
 225             return
 226           }
 227           def itPath = it.toString()
 228           if (itPath.startsWith(jalviewDirAbsolutePath+"/")) {
 229             itPath = itPath.substring(jalviewDirAbsolutePath.length()+1)
 230           }
 231           if (addedLibPath.get(itPath)) {
 232             //println("Not adding duplicate entry "+itPath)
 233           } else {
 234             //println("Adding entry "+itPath)
 235             cp.entries += new Library(fileReference(itPath))
 236             addedLibPath.put(itPath, true)
 237           }
 238         }
 239
 240         sourceSets.test.compileClasspath.each{
 241           //if ((it.isDirectory() || ! it.exists()) && ! (it.equals(sourceSets.main.java.outputDir))) {
 242           //no longer want to add outputDir as eclipse is using its own output dir in bin/main
 243           if (it.isDirectory() || ! it.exists()) {
 244             // don't add dirs to classpath
 245             return false // groovy "break" in .each loop
 246           }
 247           def itPath = it.toString()
 248           if (itPath.startsWith(jalviewDirAbsolutePath+"/")) {
 249             itPath = itPath.substring(jalviewDirAbsolutePath.length()+1)
 250           }
 251           if (addedLibPath.get(itPath)) {
 252             // don't duplicate
 253           } else {
 254             def lib = new Library(fileReference(itPath))
 255             // this doesn't work... yet.  Adding test=true attribute using withXml below
 256             //def attrs = new Node(null, 'attributes', ["test":"true"])
 257             //lib.appendNode(attrs) //
 258             cp.entries += lib
 259             addedLibPath.put(itPath, true)
 260           }
 261         }
 262       }
 263
 264       // withXml changes ignored by buildship, these add the "test=true" attribute
 265       withXml {
 266         def node = it.asNode()
 267
 268         def srcTestAttributes
 269         node.children().each{ cpe ->
 270           def attributes = cpe.attributes()
 271           if (attributes.get("kind") == "src" && attributes.get("path") == "test") {
 272             srcTestAttributes = cpe.find { a -> a.name() == "attributes" }
 273             return
 274           }
 275         }
 276         def addTestAttribute = true
 277         srcTestAttributes.each{a ->
 278           if (a.name() == "attribute" && a.attributes().getAt("name") == "test") {
 279             addTestAttribute = false
 280           }
 281         }
 282         if (addTestAttribute) {
 283           srcTestAttributes.append(new Node(null, "attribute", [name:"test", value:"true"]))
 284         }
 285
 286         node.children().each{ cpe ->
 287           def attributes = cpe.attributes()
 288           if (attributes.get("kind") == "lib" && attributes.get("path").startsWith("utils/")) {
 289             cpe.appendNode('attributes')
 290                 .appendNode('attribute', [name:"test", value:"true"])
 291           }
 292         }
 293       } // withXML
 294     } // file
 295
 296     containers 'org.eclipse.buildship.core.gradleclasspathcontainer'
 297   } // classpath
 298
 299   jdt {
 300     // for the IDE, use java 11 compatibility
 301     sourceCompatibility = 11
 302     targetCompatibility = 11
 303     javaRuntimeName = "JavaSE-11"
 304
 305     file {
 306       withProperties { props ->
 307         def jalview_prefs = new Properties()
 308         def ins = new FileInputStream(jalviewDirAbsolutePath+"/"+eclipse_extra_jdt_prefs_file)
 309         jalview_prefs.load(ins)
 310         ins.close()
 311         jalview_prefs.forEach { t, v ->
 312           if (props.getAt(t) == null) {
 313             props.putAt(t, v)
 314           }
 315         }
 316       }
 317     }
 318   }
 319
 320   //synchronizationTasks eclipseClasspath
 321   //autoBuildTasks eclipseClasspath
 322 }
 323
 324 task cloverInstr() {
 325   // only instrument source, we build test classes as normal
 326   inputs.files files (sourceSets.main.allJava) // , fileTree(dir:"$jalviewDir/$testSourceDir", include: ["**/*.java"]))
 327   outputs.dir cloverInstrDir
 328
 329   doFirst {
 330     delete cloverInstrDir
 331     def argsList = ["--initstring", "${buildDir}/clover/clover.db",
 332       "-d", "${buildDir}/${cloverSourcesInstrDir}"]
 333     argsList.addAll(inputs.files.files.collect({ file ->
 334       file.absolutePath
 335     }))
 336     String[] args = argsList.toArray()
 337     println("About to instrument "+args.length +" files")
 338     com.atlassian.clover.CloverInstr.mainImpl(args)
 339   }
 340 }
 341
 342
 343 task cloverReport {
 344   group = "Verification"
 345   description = "Createst the Clover report"
 346   inputs.dir "${buildDir}/clover"
 347   outputs.dir "${reportsDir}/clover"
 348   onlyIf {
 349     file("${buildDir}/clover/clover.db").exists()
 350   }
 351   doFirst {
 352     def argsList = ["--initstring", "${buildDir}/clover/clover.db",
 353       "-o", "${reportsDir}/clover"]
 354     String[] args = argsList.toArray()
 355     com.atlassian.clover.reporters.html.HtmlReporter.runReport(args)
 356
 357     // and generate ${reportsDir}/clover/clover.xml
 358     args = ["--initstring", "${buildDir}/clover/clover.db",
 359       "-o", "${reportsDir}/clover/clover.xml"].toArray()
 360     com.atlassian.clover.reporters.xml.XMLReporter.runReport(args)
 361   }
 362 }
 363
 364 // end clover bits
 365
 366
 367 compileJava {
 368
 369   doFirst {
 370     sourceCompatibility = compile_source_compatibility
 371     targetCompatibility = compile_target_compatibility
 372     options.compilerArgs = additional_compiler_args
 373     print ("Setting target compatibility to "+targetCompatibility+"\n")
 374   }
 375
 376 }
 377
 378 compileTestJava {
 379   if (use_clover) {
 380     dependsOn compileCloverJava
 381     classpath += configurations.cloverRuntime
 382   } else {
 383     classpath += sourceSets.main.runtimeClasspath
 384   }
 385   doFirst {
 386     sourceCompatibility = compile_source_compatibility
 387     targetCompatibility = compile_target_compatibility
 388     options.compilerArgs = additional_compiler_args
 389     print ("Setting target compatibility to "+targetCompatibility+"\n")
 390   }
 391 }
 392
 393
 394 compileCloverJava {
 395
 396   doFirst {
 397     sourceCompatibility = compile_source_compatibility
 398     targetCompatibility = compile_target_compatibility
 399     options.compilerArgs += additional_compiler_args
 400     print ("Setting target compatibility to "+targetCompatibility+"\n")
 401   }
 402   classpath += configurations.cloverRuntime
 403 }
 404
 405 clean {
 406   delete sourceSets.main.java.outputDir
 407 }
 408
 409 cleanTest {
 410   delete sourceSets.test.java.outputDir
 411   delete cloverInstrDir
 412 }
 413
 414 def getDate(format) {
 415   def date = new Date()
 416   //return date.format("dd MMMM yyyy")
 417   return date.format(format)
 418 }
 419
 420 task setGitHash(type: Exec) {
 421   workingDir = jalviewDir
 422   commandLine "git", "rev-parse", "--short", "HEAD"
 423   standardOutput = new ByteArrayOutputStream()
 424   project.ext.gitHash = {
 425     return standardOutput.toString().trim()
 426   }
 427 }
 428
 429 task setGitBranch(type: Exec) {
 430   workingDir = jalviewDir
 431   commandLine "git", "rev-parse", "--abbrev-ref", "HEAD"
 432   standardOutput = new ByteArrayOutputStream()
 433   project.ext.gitBranch = {
 434     return standardOutput.toString().trim()
 435   }
 436 }
 437
 438 task setGitVals {
 439   dependsOn setGitHash
 440   dependsOn setGitBranch
 441 }
 442
 443 task createBuildProperties(type: WriteProperties) {
 444   dependsOn setGitVals
 445   inputs.dir("$jalviewDir/$sourceDir")
 446   inputs.dir("$jalviewDir/$resourceDir")
 447   outputFile "$classes/$buildPropertiesFile"
 448   // taking time specific comment out to allow better incremental builds
 449   //comment "--Jalview Build Details--\n"+getDate("yyyy-MM-dd HH:mm:ss")
 450   comment "--Jalview Build Details--\n"+getDate("yyyy-MM-dd")
 451   property "BUILD_DATE", getDate("dd MMMM yyyy")
 452   property "VERSION", JALVIEW_VERSION
 453   property "INSTALLATION", INSTALLATION+" git-commit:"+project.ext.gitHash+" ["+project.ext.gitBranch+"]"
 454   outputs.file(outputFile)
 455   outputs.dir("$classes")
 456 }
 457
 458 def buildingHTML = "$jalviewDir/$docDir/building.html"
 459 task deleteBuildingHTML(type: Delete) {
 460   delete buildingHTML
 461 }
 462
 463 task convertBuildingMD(type: Exec) {
 464   dependsOn deleteBuildingHTML
 465   def buildingMD = "$jalviewDir/$docDir/building.md"
 466   def css = "$jalviewDir/$docDir/github.css"
 467
 468   def pandoc = pandoc_exec
 469   if (! file(pandoc).exists() && hostname.equals("jv-bamboo")) {
 470     pandoc = System.getProperty("user.home")+"/buildtools/pandoc/bin/pandoc"
 471   }
 472
 473   if (file(pandoc).exists()) {
 474     commandLine pandoc, '-s', '-o', buildingHTML, '--metadata', 'pagetitle="Building Jalview from Source"', '--toc', '-H', css, buildingMD
 475   }
 476   ignoreExitValue true
 477
 478   inputs.file(buildingMD)
 479   inputs.file(css)
 480   outputs.file(buildingHTML)
 481 }
 482 clean {
 483   delete buildingHTML
 484 }
 485
 486 task syncDocs(type: Sync) {
 487   dependsOn convertBuildingMD
 488   def syncDir = "$classes/$docDir"
 489   from fileTree("$jalviewDir/$docDir")
 490   into syncDir
 491
 492 }
 493
 494 def helpFile = "$classes/$helpDir/help.jhm"
 495
 496 task copyHelp(type: Copy) {
 497   def inputDir = "$jalviewDir/$helpParentDir/$helpDir"
 498   def outputDir = "$classes/$helpDir"
 499   from(inputDir) {
 500     exclude '**/*.gif'
 501     exclude '**/*.jpg'
 502     exclude '**/*.png'
 503     filter(ReplaceTokens, beginToken: '$$', endToken: '$$', tokens: ['Version-Rel': JALVIEW_VERSION])
 504   }
 505   from(inputDir) {
 506     include '**/*.gif'
 507     include '**/*.jpg'
 508     include '**/*.png'
 509   }
 510   into outputDir
 511
 512   inputs.dir(inputDir)
 513   outputs.files(helpFile)
 514   outputs.dir(outputDir)
 515 }
 516
 517 task syncLib(type: Sync) {
 518   def syncDir = "$classes/$libDistDir"
 519   from fileTree("$jalviewDir/$libDistDir")
 520   into syncDir
 521 }
 522
 523 task syncResources(type: Sync) {
 524   from "$jalviewDir/$resourceDir"
 525   include "**/*.*"
 526   exclude "install4j"
 527   into "$classes"
 528   preserve {
 529     include "**"
 530   }
 531 }
 532
 533 task prepare {
 534   dependsOn syncResources
 535   dependsOn syncDocs
 536   dependsOn copyHelp
 537 }
 538
 539
 540 //testReportDirName = "test-reports" // note that test workingDir will be $jalviewDir
 541 test {
 542   dependsOn prepare
 543   dependsOn compileJava
 544   if (use_clover) {
 545     dependsOn cloverInstr
 546   }
 547
 548   print("Running tests " + (use_clover?"WITH":"WITHOUT") + " clover [clover="+use_clover+"]\n")
 549
 550   useTestNG() {
 551     includeGroups testngGroups
 552     preserveOrder true
 553     useDefaultListeners=true
 554   }
 555
 556   workingDir = jalviewDir
 557   //systemProperties 'clover.jar' System.properties.clover.jar
 558   sourceCompatibility = compile_source_compatibility
 559   targetCompatibility = compile_target_compatibility
 560   jvmArgs += additional_compiler_args
 561   print ("Setting target compatibility to "+targetCompatibility+"\n")
 562 }
 563
 564 task buildIndices(type: JavaExec) {
 565   dependsOn copyHelp
 566   classpath = sourceSets.main.compileClasspath
 567   main = "com.sun.java.help.search.Indexer"
 568   workingDir = "$classes/$helpDir"
 569   def argDir = "html"
 570   args = [ argDir ]
 571   inputs.dir("$workingDir/$argDir")
 572
 573   outputs.dir("$classes/doc")
 574   outputs.dir("$classes/help")
 575   outputs.file("$workingDir/JavaHelpSearch/DOCS")
 576   outputs.file("$workingDir/JavaHelpSearch/DOCS.TAB")
 577   outputs.file("$workingDir/JavaHelpSearch/OFFSETS")
 578   outputs.file("$workingDir/JavaHelpSearch/POSITIONS")
 579   outputs.file("$workingDir/JavaHelpSearch/SCHEMA")
 580   outputs.file("$workingDir/JavaHelpSearch/TMAP")
 581 }
 582
 583 task compileLinkCheck(type: JavaCompile) {
 584   options.fork = true
 585   classpath = files("$jalviewDir/$utilsDir")
 586   destinationDir = file("$jalviewDir/$utilsDir")
 587   source = fileTree(dir: "$jalviewDir/$utilsDir", include: ["HelpLinksChecker.java", "BufferedLineReader.java"])
 588
 589   inputs.file("$jalviewDir/$utilsDir/HelpLinksChecker.java")
 590   inputs.file("$jalviewDir/$utilsDir/HelpLinksChecker.java")
 591   outputs.file("$jalviewDir/$utilsDir/HelpLinksChecker.class")
 592   outputs.file("$jalviewDir/$utilsDir/BufferedLineReader.class")
 593 }
 594
 595 def helplinkscheckeroutputfile = file("$jalviewDir/$utilsDir/HelpLinksChecker.out")
 596 task linkCheck(type: JavaExec) {
 597   dependsOn prepare, compileLinkCheck
 598   classpath = files("$jalviewDir/$utilsDir")
 599   main = "HelpLinksChecker"
 600   workingDir = jalviewDir
 601   def help = "$classes/$helpDir"
 602   args = [ "$classes/$helpDir", "-nointernet" ]
 603
 604   doFirst {
 605     helplinkscheckeroutputfile.createNewFile()
 606     standardOutput new FileOutputStream(helplinkscheckeroutputfile, false)
 607   }
 608
 609   outputs.file(helplinkscheckeroutputfile)
 610 }
 611
 612 task cleanPackageDir(type: Delete) {
 613   delete fileTree("$jalviewDir/$packageDir").include("*.jar")
 614 }
 615
 616 jar {
 617   dependsOn linkCheck
 618   dependsOn buildIndices
 619   dependsOn createBuildProperties
 620
 621   manifest {
 622     attributes "Main-Class": mainClass,
 623     "Permissions": "all-permissions",
 624     "Application-Name": "Jalview Desktop",
 625     "Codebase": application_codebase
 626   }
 627
 628   destinationDir = file("$jalviewDir/$packageDir")
 629   archiveName = rootProject.name+".jar"
 630
 631   exclude "cache*/**"
 632   exclude "*.jar"
 633   exclude "*.jar.*"
 634   exclude "**/*.jar"
 635   exclude "**/*.jar.*"
 636
 637   inputs.dir("$classes")
 638   outputs.file("$jalviewDir/$packageDir/$archiveName")
 639 }
 640
 641 task copyJars(type: Copy) {
 642   from fileTree("$classes").include("**/*.jar").include("*.jar").files
 643   into "$jalviewDir/$packageDir"
 644 }
 645
 646 // doing a Sync instead of Copy as Copy doesn't deal with "outputs" very well
 647 task syncJars(type: Sync) {
 648   from fileTree("$jalviewDir/$libDistDir").include("**/*.jar").include("*.jar").files
 649   into "$jalviewDir/$packageDir"
 650   preserve {
 651     include jar.archiveName
 652   }
 653 }
 654
 655 task makeDist {
 656   group = "build"
 657   description = "Put all required libraries in dist"
 658   // order of "cleanPackageDir", "copyJars", "jar" important!
 659   jar.mustRunAfter cleanPackageDir
 660   syncJars.mustRunAfter cleanPackageDir
 661   dependsOn cleanPackageDir
 662   dependsOn syncJars
 663   dependsOn jar
 664   outputs.dir("$jalviewDir/$packageDir")
 665 }
 666
 667 task cleanDist {
 668   dependsOn cleanPackageDir
 669   dependsOn cleanTest
 670   dependsOn clean
 671 }
 672
 673 shadowJar {
 674   group = "distribution"
 675   dependsOn makeDist
 676   from ("$jalviewDir/$libDistDir") {
 677     include("*.jar")
 678   }
 679   mainClassName = shadowJarMainClass
 680   mergeServiceFiles()
 681   classifier = "all-"+JAVA_VERSION
 682   minimize()
 683 }
 684
 685 task getdownWebsite() {
 686   group = "distribution"
 687   description = "Create the getdown minimal app folder, and website folder for this version of jalview. Website folder also used for offline app installer"
 688   dependsOn makeDist
 689   def getdownWebsiteResourceFilenames = []
 690   def getdownTextString = ""
 691   def getdownResourceDir = project.ext.getdownResourceDir
 692   def getdownAppDir = project.ext.getdownAppDir
 693   def getdownResourceFilenames = []
 694   doFirst {
 695     // go through properties looking for getdown_txt_...
 696     def props = project.properties.sort { it.key }
 697     props.put("getdown_txt_java_min_version", getdown_alt_java_min_version)
 698     props.put("getdown_txt_multi_java_location", getdown_alt_multi_java_location)
 699
 700     if (getdown_local == "true") {
 701       getdown_app_base = file(getdownWebsiteDir).toURI().toString()
 702     }
 703     props.put("getdown_txt_appbase", getdown_app_base)
 704     props.each{ prop, val ->
 705       if (prop.startsWith("getdown_txt_") && val != null) {
 706         if (prop.startsWith("getdown_txt_multi_")) {
 707           def key = prop.substring(18)
 708           val.split(",").each{ v ->
 709             def line = key + " = " + v + "\n"
 710             getdownTextString += line
 711           }
 712         } else {
 713           // file values rationalised
 714           if (val.indexOf('/') > -1) {
 715             def r = null
 716             if (val.indexOf('/') == 0) {
 717               // absolute path
 718               r = file(val)
 719             } else if (val.indexOf('/') > 0) {
 720               // relative path (relative to jalviewDir)
 721               r = file( jalviewDir + '/' + val )
 722             }
 723             if (r.exists()) {
 724               val = getdown_resource_dir + '/' + r.getName()
 725               getdownWebsiteResourceFilenames += val
 726               getdownResourceFilenames += r.getPath()
 727             }
 728           }
 729           def line = prop.substring(12) + " = " + val + "\n"
 730           getdownTextString += line
 731         }
 732       }
 733     }
 734
 735     getdownWebsiteResourceFilenames.each{ filename ->
 736       getdownTextString += "resource = "+filename+"\n"
 737     }
 738     getdownResourceFilenames.each{ filename ->
 739       copy {
 740         from filename
 741         into project.ext.getdownResourceDir
 742       }
 743     }
 744
 745     def codeFiles = []
 746     makeDist.outputs.files.each{ f ->
 747       if (f.isDirectory()) {
 748         def files = fileTree(dir: f, include: ["*"]).getFiles()
 749         codeFiles += files
 750       } else if (f.exists()) {
 751         codeFiles += f
 752       }
 753     }
 754     codeFiles.sort().each{f ->
 755       def line = "code = " + getdown_app_dir + '/' + f.getName() + "\n"
 756       getdownTextString += line
 757       copy {
 758         from f.getPath()
 759         into project.ext.getdownAppDir
 760       }
 761     }
 762
 763     // NOT USING MODULES YET, EVERYTHING SHOULD BE IN dist
 764     /*
 765      if (JAVA_VERSION.equals("11")) {
 766      def j11libFiles = fileTree(dir: "$jalviewDir/$j11libDir", include: ["*.jar"]).getFiles()
 767      j11libFiles.sort().each{f ->
 768      def line = "code = " + getdown_j11lib_dir + '/' + f.getName() + "\n"
 769      getdownTextString += line
 770      copy {
 771      from f.getPath()
 772      into project.ext.getdownJ11libDir
 773      }
 774      }
 775      }
 776      */
 777
 778     // getdown-launcher.jar should not be in main application class path so the main application can move it when updated.  Listed as a resource so it gets updated.
 779     //getdownTextString += "class = " + file(getdownLauncher).getName() + "\n"
 780     getdownTextString += "resource = " + file(getdownLauncher).getName() + "\n"
 781     getdownTextString += "class = " + mainClass + "\n"
 782
 783     def getdown_txt = file(project.ext.getdownWebsiteDir + "/getdown.txt")
 784     getdown_txt.write(getdownTextString)
 785
 786     copy {
 787       from getdown_txt
 788       into project.ext.getdownFilesDir
 789     }
 790
 791     copy {
 792       from getdownLauncher
 793       into project.ext.getdownFilesDir
 794     }
 795
 796     copy {
 797       from getdownLauncher
 798       into project.ext.getdownWebsiteDir
 799     }
 800
 801     copy {
 802       from jalviewDir + '/' + project.getProperty('getdown_txt_ui.background_image')
 803       from jalviewDir + '/' + project.getProperty('getdown_txt_ui.error_background')
 804       from jalviewDir + '/' + project.getProperty('getdown_txt_ui.progress_image')
 805       from jalviewDir + '/' + project.getProperty('getdown_txt_ui.icon')
 806       from jalviewDir + '/' + project.getProperty('getdown_txt_ui.mac_dock_icon')
 807       into project.ext.getdownFilesDir + '/' + getdown_resource_dir
 808     }
 809   }
 810
 811   inputs.dir(jalviewDir + '/' + packageDir)
 812   outputs.dir(project.ext.getdownWebsiteDir)
 813   outputs.dir(project.ext.getdownFilesDir)
 814 }
 815
 816 task getdownDigest(type: JavaExec) {
 817   group = "distribution"
 818   description = "Digest the getdown website folder"
 819   dependsOn getdownWebsite
 820   classpath = files(jalviewDir + '/' + getdown_core, jalviewDir+'/'+getdown_launcher)
 821   main = "com.threerings.getdown.tools.Digester"
 822   args project.ext.getdownWebsiteDir
 823   inputs.dir(project.ext.getdownWebsiteDir)
 824   outputs.file(project.ext.getdownWebsiteDir + '/' + "digest2.txt")
 825 }
 826
 827 task getdown() {
 828   group = "distribution"
 829   description = "Create the minimal and full getdown app folder for installers and website and create digest file"
 830   dependsOn getdownDigest
 831 }
 832
 833 clean {
 834   delete project.ext.getdownWebsiteDir
 835   delete project.ext.getdownFilesDir
 836 }
 837
 838 install4j {
 839   def install4jHomeDir = "/opt/install4j"
 840   def hostname = "hostname".execute().text.trim()
 841   if (hostname.equals("jv-bamboo")) {
 842     install4jHomeDir = System.getProperty("user.home")+"/buildtools/install4j"
 843   } else if (OperatingSystem.current().isMacOsX()) {
 844     install4jHomeDir = '/Applications/install4j.app/Contents/Resources/app'
 845     if (! file(install4jHomeDir).exists()) {
 846       install4jHomeDir = System.getProperty("user.home")+install4jHomeDir
 847     }
 848   } else if (OperatingSystem.current().isLinux()) {
 849     install4jHomeDir = System.getProperty("user.home")+"/buildtools/install4j"
 850   }
 851   installDir = file(install4jHomeDir)
 852   mediaTypes = Arrays.asList(install4jMediaTypes.split(","))
 853   if (install4jFaster.equals("true")) {
 854     faster = true
 855   }
 856 }
 857
 858 def install4jConf
 859 def macosJavaVMDir
 860 def macosJavaVMTgz
 861 def windowsJavaVMDir
 862 def windowsJavaVMTgz
 863 def install4jDir = "$jalviewDir/$install4jResourceDir"
 864 def install4jConfFile = "jalview-installers-java"+JAVA_VERSION+".install4j"
 865 install4jConf = "$install4jDir/$install4jConfFile"
 866
 867 task copyInstall4jTemplate(type: Copy) {
 868   macosJavaVMDir = System.env.HOME+"/buildtools/jre/openjdk-java_vm/getdown/macos-jre"+JAVA_VERSION+"/jre"
 869   macosJavaVMTgz = System.env.HOME+"/buildtools/jre/openjdk-java_vm/install4j/tgz/macos-jre"+JAVA_VERSION+".tar.gz"
 870   windowsJavaVMDir = System.env.HOME+"/buildtools/jre/openjdk-java_vm/getdown/windows-jre"+JAVA_VERSION+"/jre"
 871   windowsJavaVMTgz = System.env.HOME+"/buildtools/jre/openjdk-java_vm/install4j/tgz/windows-jre"+JAVA_VERSION+".tar.gz"
 872   from (install4jDir) {
 873     include install4jTemplate
 874     rename (install4jTemplate, install4jConfFile)
 875     filter(ReplaceTokens, beginToken: '', endToken: '', tokens: ['9999999999': JAVA_VERSION])
 876     filter(ReplaceTokens, beginToken: '$$', endToken: '$$',
 877       tokens: [
 878         'JAVA_VERSION': JAVA_VERSION,
 879         'JAVA_INTEGER_VERSION': JAVA_INTEGER_VERSION,
 880         'VERSION': JALVIEW_VERSION,
 881         'MACOS_JAVA_VM_DIR': macosJavaVMDir,
 882         'MACOS_JAVA_VM_TGZ': macosJavaVMTgz,
 883         'WINDOWS_JAVA_VM_DIR': windowsJavaVMDir,
 884         'WINDOWS_JAVA_VM_TGZ': windowsJavaVMTgz,
 885         'INSTALL4JINFOPLISTFILEASSOCIATIONS': install4jInfoPlistFileAssociations,
 886         'COPYRIGHT_MESSAGE': install4jCopyrightMessage,
 887         'MACOS_BUNDLE_ID': install4jMacOSBundleId
 888       ]
 889     )
 890     if (OSX_KEYPASS=="") {
 891       filter(ReplaceTokens, beginToken: 'codeSigning macEnabled="', endToken: '"', tokens: ['true':'codeSigning macEnabled="false"'])
 892       filter(ReplaceTokens, beginToken: 'runPostProcessor="true" ',endToken: 'Processor', tokens: ['post':'runPostProcessor="false" postProcessor'])
 893     }
 894   }
 895   into install4jDir
 896   outputs.files(install4jConf)
 897
 898   doLast {
 899     // include file associations in installer
 900     def installerFileAssociationsXml = file("$install4jDir/$install4jInstallerFileAssociations").text
 901     ant.replaceregexp(
 902       byline: false,
 903       flags: "s",
 904       match: '<action name="EXTENSIONS_REPLACED_BY_GRADLE".*?</action>',
 905       replace: installerFileAssociationsXml,
 906       file: install4jConf
 907     )
 908     /*
 909     // include uninstaller applescript app files in dmg
 910     def installerDMGUninstallerXml = file("$install4jDir/$install4jDMGUninstallerAppFiles").text
 911     ant.replaceregexp(
 912       byline: false,
 913       flags: "s",
 914       match: '<file name="UNINSTALL_OLD_JALVIEW_APP_REPLACED_IN_GRADLE" file=.*?>',
 915       replace: installerDMGUninstallerXml,
 916       file: install4jConf
 917     )
 918     */
 919   }
 920 }
 921
 922 task installers(type: com.install4j.gradle.Install4jTask) {
 923   group = "distribution"
 924   description = "Create the install4j installers"
 925   dependsOn getdown
 926   dependsOn copyInstall4jTemplate
 927   projectFile = file(install4jConf)
 928   println("Using projectFile "+projectFile)
 929   variables = [majorVersion: version.substring(2, 11), build: 001, OSX_KEYSTORE: OSX_KEYSTORE, JSIGN_SH: JSIGN_SH]
 930   destination = "$jalviewDir/$install4jBuildDir/$JAVA_VERSION"
 931   buildSelected = true
 932
 933   if (OSX_KEYPASS) {
 934     macKeystorePassword=OSX_KEYPASS
 935
 936   }
 937
 938   inputs.dir(project.ext.getdownWebsiteDir)
 939   inputs.file(install4jConf)
 940   inputs.dir(macosJavaVMDir)
 941   inputs.dir(windowsJavaVMDir)
 942   outputs.dir("$jalviewDir/$install4jBuildDir/$JAVA_VERSION")
 943 }
 944
 945 clean {
 946   delete install4jConf
 947 }